Как выделить ячейку, используя шестнадцатеричное значение цвета внутри ячейки?

Невозможно использовать условное форматирование для всех цветов.

Предполагая: строка 1 содержит метки данных, набор данных не имеет пробелов, цвет HEX предназначен для заливки, а не для шрифта, вы проанализировали значения цвета HEX (числа, а не формулы) в столбцах C: E (R, G, B) и что вам не требуется делать это часто, то может подойти макрос ColourCells:

Sub ColourCells()
Dim HowMany As Integer
On Error Resume Next
Application.DisplayAlerts = False
HowMany = Application.InputBox _
(Prompt:="Enter last row number.", Title:="To apply to how many rows?", Type:=1)
On Error GoTo 0
Application.DisplayAlerts = True
If HowMany = 0 Then
Exit Sub
Else
   Dim i As Integer
   For i = 2 To HowMany
      Cells(i, 3).Interior.Color = RGB(Cells(i, 3), Cells(i, 4), Cells(i, 5))
   Next i
End If
End Sub

и введите желаемое значение для n при появлении запроса.

Пример вывода и формулы и т.д.:

Функция Excel RGB() фактически создает значение BGR (я не думаю, что кто-то, кто может знать, почему, говорит, почему), поэтому Excel показывает кусочки в обратном порядке. Поскольку код Columns3,4,5 был логичным, но BGR, а не обычный RGB в изображении, я подумал, может выглядеть странно. Для F на изображении значение C3 (столбец LEFT из трех столбцов RGB) получается путем применения RIGHT() к шестнадцатеричному цвету.

Незначительное редактирование ответа Джона Пельтье. Его функция ПОЧТИ работает, но цвета, которые она отображает, неверны из-за того, что Excel будет отображать как BGR, а не RGB. Вот исправленная функция, которая меняет пары шестнадцатеричных значений в «правильном» порядке:

Sub ColorCellsByHex()
  Dim rSelection As Range, rCell As Range, tHex As String

  If TypeName(Selection) = "Range" Then
  Set rSelection = Selection
    For Each rCell In rSelection
      tHex = Mid(rCell.Text, 6, 2) & Mid(rCell.Text, 4, 2) & Mid(rCell.Text, 2, 2)
      rCell.Interior.Color = WorksheetFunction.Hex2Dec(tHex)
    Next
  End If
End Sub

Гораздо проще:

ActiveCell.Interior.Color = WorksheetFunction.Hex2Dec(Mid$(ActiveCell.Text, 2))

Mid удаляет начальный «#», Hex2Dec превращает шестнадцатеричное число в десятичное значение, которое может использовать VBA.

Итак, выберите диапазон для обработки и запустите это:

Sub ColorCellsByHexInCells()
  Dim rSelection As Range, rCell As Range

  If TypeName(Selection) = "Range" Then
  Set rSelection = Selection
    For Each rCell In rSelection
      rCell.Interior.Color = WorksheetFunction.Hex2Dec(Mid$(rCell.Text, 2))
    Next
  End If
End Sub

Нет необходимости многократно преодолевать барьер VBA/Worksheet для преобразования. Эта оптимизированная версия имеет правильный порядок байтов:

Sub ColorCellsByHex()
    Dim r
    If TypeName(Selection) <> "Range" Then Exit Sub
    For Each r In Selection
        r.Interior.Color = Abs(("&H" & Mid(r, 6, 2) & Mid(r, 4, 2) & Mid(r, 2, 2)))
    Next
End Sub

Для этого пользовательскую форму можно создать с помощью функции Hex2Dec.

Function Hex2Dec(n1 As String) As Long
    Dim nl1 As Long
    Dim nGVal As Long
    Dim nSteper As Long
    Dim nCount As Long
    Dim x As Long
    Dim nVal As Long
    Dim Stepit As Long
    Dim hVal As String

    nl1 = Len(n1)
    nGVal = 0
    nSteper = 16
    nCount = 1
    For x = nl1 To 1 Step -1
       hVal = UCase(Mid$(n1, x, 1))
       Select Case hVal
         Case "A"
           nVal = 10
         Case "B"
           nVal = 11
         Case "C"
           nVal = 12
         Case "D"
           nVal = 13
         Case "E"
           nVal = 14
         Case "F"
           nVal = 15
         Case Else
           nVal = Val(hVal)
       End Select
       Stepit = (nSteper ^ (nCount - 1))
       nGVal = nGVal + nVal * Stepit
       nCount = nCount + 1
    Next x
    Hex2Dec = nGVal
End Function
...
UserForm1.TextBox1 = "RGB(" & Hex2Dec(UserForm1.txtHex1.Value) & "," & _
           Hex2Dec(UserForm1.txtHex2.Value) & "," & Hex2Dec(UserForm1.txtHex3.Value) & ")"

Например, введенное значение в текстовое поле: #FF8800 - Результат: RGB(255,136,0)

Это еще один вариант — он обновляет цвет ячейки, когда вы выбираете ячейку, предполагая, что значение в ячейке начинается с «#» и составляет 7 символов.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If (Left(ActiveCell.Text, 1) = "#" And Len(ActiveCell.Text) = 7) Then
    ActiveCell.Interior.Color = WorksheetFunction.Hex2Dec(Mid$(ActiveCell.Text, 2))
End If

End Sub