Как улучшить структуру кода AS3, чтобы сделать ее более эффективной?

Реструктуризация:

public class EuroCup extends Sprite {
    private var arr:Array;

    public function EuroCup() {
        arr = [ new Result609(), new Result610(),
                new Result611(), new Result612(), new Result613()
              ];
    }
}

Затем используйте результаты как arr[0], arr[1] и так далее. Кроме того, если у вас есть несколько спрайтов для прослушивания кликов с похожими слушателями, вы можете подключить все такие спрайты к отдельным слушателям и использовать event.target, чтобы различать их, где событием является MouseEvent. Или поместите их в контейнер и создайте один слушатель для этого контейнера — опять же, event.target сообщит, какой спрайт был нажат.
И еще две вещи — каждый раз, когда вы видите new Array(), заменяйте его на [] — так быстрее и короче. И поместите весь код в конструктор, а не в тело класса - он будет скомпилирован для более быстрого выполнения.

Вы можете/должны использовать словарь для ассоциаций между серыми прямоугольниками и отображаемыми изображениями.

package {
  public class EuroCup {

    private var _children:Array, _current:Sprite, _map:Dictionary;

    public function EuroCup() {
      super();
      initialize();
    }

    protected function initialize():void {
      _children = [];
      _map = new Dictonary();

      // i don't know the image's symbol name.
      // _map[_children[_children.length] = new Result609()] = new SYMBOL_NAME();

      for each(var child:Sprite in _children) {
        child.addEventListener(MouseEvent.CLICK, click_handler);
      }
    }

    private function click_handler(event:MouseEvent):void
    {
      if (_current) {
        _current.visible = false; // or use fading, etc
      }

      _current = _map[event.currentTarget] as Sprite;

      if (_current) {
        _current.visible = true; // or use fading, etc
      }
    }
  }
}

Один из вариантов упрощения кода — связать экземпляры sp и Res друг с другом по идентификатору с помощью Словаря. Это позволяет вам избежать работы по отслеживанию индексов массива, что является половиной причины, по которой у вас есть отдельные методы обработчика событий. После того, как экземпляры связаны по идентификатору, вы можете использовать свойство currentTarget отправленного события, чтобы определить, какой элемент словаря вы хотите отобразить на сцене.

package  {
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.events.Event;
import flash.utils.Dictionary;

public class test extends Sprite
{
    var dict:Dictionary = new Dictionary();
    var visibleResult:MovieClip;

    public function test()
    {
        dict[sp1]=new Result609();
        dict[sp2]=new Result610();
        dict[sp3]=new Result611();
        dict[sp4]=new Result612();
        dict[sp5]=new Result613();

        sp1.addEventListener(MouseEvent.MOUSE_OVER,clickmouse);
        sp2.addEventListener(MouseEvent.MOUSE_OVER,clickmouse);
        sp3.addEventListener(MouseEvent.MOUSE_OVER,clickmouse);
        sp4.addEventListener(MouseEvent.MOUSE_OVER,clickmouse);
        sp5.addEventListener(MouseEvent.MOUSE_OVER,clickmouse);
    }

    private function clickmouse(evt:MouseEvent):void
    {
        if(visibleResult)
        {
            removeChild(visibleResult);
        }
        var Res:MovieClip = dict[evt.currentTarget] as MovieClip;
        addChild(Res);
        Res.x=300;
        Res.y=400;
        visibleResult=Res;
    }
}
}

Если вы ожидаете, что в приложении будет более 5 экземпляров sp, вы можете использовать цикл для назначения прослушивателей событий. Но для менее чем 10 экземпляров вы, вероятно, мало что выиграете от цикла.

Я бы выбрал более простую версию; добавьте только один прослушиватель событий и используйте Event.target, чтобы определить, какой элемент нажат, используя оператор switch.

Это полезно, если кнопки должны выполнять разные функции.

package  
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;

    public class Test extends Sprite
    {
        public var sp1:Sprite;
        public var sp2:Sprite;
        public var sp3:Sprite;

        public function Test()
        {  
            this.addEventListener(MouseEvent.MOUSE_OVER, handleClick);
        }

        private function handleClick(event:MouseEvent):void
        {
            trace("Clicked on: " + event.target)
            switch (event.target)
            {
                case this.sp1:
                {
                    // do something here
                    break;
                }
                case this.sp2:
                {
                    // do something here
                    break;
                }
                case this.sp3:
                {
                    // do something here
                    break;
                }
                default
                {
                    trace("No handler defined for: " + event.target)
                }
            }   
        }
    }
}

Тем не менее, вы также можете разумно использовать его тип. Допустим, все ваши кнопки расширяют пользовательский класс с именем CustomButton, и все они должны делать одно и то же (например, вызывать функцию), но с параметром, основанным на его идентификаторе.

Это полезно, если кнопки должны делать одно и то же.

package  
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;

    public class Test extends Sprite
    {
        public function Test()
        {  
            this.addEventListener(MouseEvent.MOUSE_OVER, handleClick);
        }

        private function handleClick(event:MouseEvent):void
        {
            if (event.target is CustomButton)
            {
                var button:CustomButton = event.target as CustomButton; // you're now sure it's a CustomButton
                this.showById(button.id); // let's say CustomButton has a public var 'id'
            }
        }

        private function showById(id:int):void
        {
            // do something
        }
    }
}

Надеюсь, это поможет.

Совет. Всегда начинайте имя класса и файла с заглавной буквы. Переменные начинаются с заглавных букв. Это очень распространено в мире actionscript.