Обработка события класса с помощью обычной процедуры (Delphi)

Если у вас нет подходящего класса для размещения обработчиков событий, вы можете определить фиктивный класс и сделать обработчики событий class procedures. Тогда вам не нужно создавать экземпляр класса, но вы можете назначить mydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError;.

Вот пример: я использую разные события, потому что у меня нет TUniConnection, но я хочу убедиться, что все компилируется. :-)

type
  // Dummy class to hold event handlers:
  TXMLEventHandlers = class
    // Event handlers:
    class procedure OnBeforeOpen(Sender: TObject);
    class procedure OnAfterOpen(Sender: TObject);
  end;

class procedure TXMLEventHandlers.OnBeforeOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnBeforeOpen'), nil, 0)
end;

class procedure TXMLEventHandlers.OnAfterOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnAfterOpen'), nil, 0)
end;

procedure Test;
var
  xml: TXMLDocument;
begin
  xml := TXMLDocument.Create(nil);
  try
    // Note: No instance of `TXMLEventHandlers` must be created:
    xml.AfterOpen := TXMLEventHandlers.OnAfterOpen;
    xml.BeforeOpen := TXMLEventHandlers.OnBeforeOpen;

    xml.Active := True; // Calls the two event handlers
  finally
    xml.Free;
  end;
end;

Если вы не хотите создавать экземпляр класса в куче, вы можете использовать методы записи. Иногда я делаю это, чтобы не использовать кучу, но такой подход может быть удобен для ваших нужд.

type
  TMyEventHandler = record
    procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
    procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
  end;

procedure TMyEventHandler.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ....
end;

procedure TMyEventHandler.OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ....
end;

var
  EventHandler: TEventHandler;//global variable

......

mydb.OnError := EventHandler.OnConnectionError;
mydb.OnConnectionLost := EventHandler.OnConnectionLost;

Две ваши процедуры обработки событий должны быть методами класса, а не локальными/глобальными процедурами. Например:

procedure TForm1.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);

Хотя использование метода class является чистым решением, возможно использовать обычную неклассовую процедуру в качестве обработчика событий, вы просто не можете назначить ее напрямую, но вы можете назначить его косвенно с помощью записи TMethod . Вам просто нужно добавить в процедуру явный параметр Self.

Например:

procedure OnConnectionError(Self: Pointer; Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ...
end;

procedure OnConnectionLost(Self: Pointer; Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ...
end;

var
  M: TMethod;
begin
  M.Data := ... whatever you want ...;
  M.Code := @OnConnectionError;
  mydb.OnError := TDAConnectionErrorEvent(M);

  M.Data := ... whatever you want ...;
  M.Code := @OnConnectionLost;
  mydb.OnConnectionLost := TConnectionLostEvent(M);
end;

В качестве альтернативы:

procedure OnConnectionError(Self: Pointer; Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ...
end;

procedure OnConnectionLost(Self: Pointer; Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ...
end;

var
  ErrorHandler: TDAConnectionErrorEvent;
  LostHandler: TConnectionLostEvent;
begin
  TMethod(ErrorHandler).Data := ... whatever you want ...;
  TMethod(ErrorHandler).Code := @OnConnectionError;
  mydb.OnError := ErrorHandler;

  TMethod(LostHandler).Data := ... whatever you want ...;
  TMethod(LostHandler).Code := @OnConnectionLost;
  mydb.OnConnectionLost := LostHandler;
end;

Преимущество этого подхода заключается в том, что вы можете установить для параметра Self любое значение, которое вы хотите, что полезно для передачи пользовательских данных в обработчик событий.