Как выполнить экранирование оболочки POSIX из Tcl

Вы можете ' заключать в кавычки все не-' символы вместе, а не по отдельности, и вам нужно только закончить и возобновить '-кавычки в середине строки, чтобы \-экранировать любые ' символы.

Так что вы были на правильном пути со спамом '-quote, потому что вы уже поняли

1. что одинарные кавычки экранируют все (кроме '), что сокращает число особых случаев до одного, и
2. что вы можете просто объединить строки в кавычках в оболочке, и она интерпретирует их как одну строку ('a''b' анализирует ту же необработанную строку, что и 'ab').

Последний недостающий элемент заключался в том, что второй пункт позволяет нам оптимизировать почти все окончание и немедленное возобновление '-цитирования, которое происходило при '-цитировании каждого символа по отдельности.

Так что логика, которая вам нужна, это просто

1. замените все ' на '\'' и
2. поставьте один ' в начале и в конце:

proc posix_escape_via_minimal_quotes {name} {
  set escaped {}
  lappend escaped '
  lappend escaped [string map {' '\\''} $name]
  lappend escaped '
  return [join $escaped {}]
}

Пример выходных данных:

% posix_escape_via_minimal_quotes x
'x'
% posix_escape_via_minimal_quotes xxx
'xxx'
% posix_escape_via_minimal_quotes xxx'xxx
'xxx'\''xxx'
% posix_escape_via_minimal_quotes '
''\'''

Ключом к этому является использование string map или regsub.

Использование string map для преобразования набора символов

Все, что вам нужно сделать, это предоставить правильное сопоставление для вещей, которые вы хотите скрыть.

В вашем конкретном случае единственными символами, которые вы хотите указать, являются ', ", $, (, ), <, > и |. Давайте также добавим ;, * и ? (я предполагаю, что вам не нужны случайные разделители операторов или подстановочные символы). Это довольно просто, но мы будем генерировать сопоставление итеративно, а не использовать литерал:

set mappedChars {'"$()<>|&!;*?}    ;#'# Just to deal with SO's formatting...
set escaping {}
foreach c $mappedChars { lappend escaping $c "\\$c" }

Это то, что вам нужно сделать только один раз. После этого применить карту легко:

set escapedTargets [string map $escaping $targets]

Я оставлю это вам, чтобы найти лучший способ объединить это с вашим использованием subst.

Использование regsub для преобразования набора символов

Другой метод — использовать regsub с опцией -all. Это действительно хорошо работает только в том случае, если вы делаете один и тот же тип экранирования во всех замещенных случаях.

# This puts a backslash in front of all non-alphanumerics
set escapedTargets [regsub -all {[^[:alnum:]]} $targets {\\&}]

# This _particular_ case has an almost-equivalent-good-enough that's shorter
set escapedTargets [regsub -all {\W} $targets {\\&}]

Сложность заключается в определении правильного регулярного выражения характеристики для всех ваших проблемных случаев, поэтому часто утверждается, что использование регулярных выражений превращает одну проблему в две…

Обсуждение / Альтернативные подходы

Приведенная выше карта не охватывает все метасимволы оболочки POSIX — в частности, она не обрабатывает саму обратную косую черту или пробелы (это может вызвать проблемы, поскольку вы хотите получить несколько слов), и она также должна обрабатывать следующие: {}[]~ — и регулярное выражение, возможно, немного слишком остроумно, ставя обратную косую черту перед совершенно невинными вещами. Действительно, некоторые виды использования (например, имена переменных) требуют гораздо большей осторожности, чем любой из вышеперечисленных подходов, поскольку в них есть вещи, которые просто нельзя использовать.

Основная проблема заключается в том, что оболочка на самом деле имеет очень сложный синтаксис с множеством взаимодействующих правил. Если вы можете написать свой код так, чтобы не требовался запуск оболочки, вы, вероятно, найдете вещи гораздо более надежными (по модулю того факта, что Tcl exec и конвейер open имеют свои собственные странные проблемы, которые возникают из-за слишком многого, чтобы быть похожим на оболочку) . Подходит ли это для вас, зависит от других вещей, о которых вы не сказали нам в своем вопросе.

В итоге я применил вариант упомянутого мной метода «рассылки спама с цитатами», но в специальном регистре различные классы символов, которые либо никогда не нужно заключать в кавычки, либо могут заключаться в кавычки с простой обратной косой чертой. Это все еще немного чрезмерно, но НАМНОГО лучше, чем оригинальный наивный подход. В большинстве случаев это дает тот же результат, что и метод bash printf.

  proc posix_escape {name} {
    foreach char [split $name {}] {
      switch -regexp $char {
        {'}           {append escaped \\'     }
        {[[:alnum:]]} {append escaped $char   }
        {[[:space:]]} {append escaped \\$char }
        {[[:punct:]]} {append escaped \\$char }
        default       {append escaped '$char' }
      }
    }
    return $escaped
  }

Мне все еще очень интересно, есть ли более стандартный способ сделать это. Меня бы очень удивило, если бы никто никогда не сталкивался с этим раньше! знак равно