Обнаружение завершения фонового процесса TCL в сценарии TCL

Как отметил @glenn-jackman, предпочтительнее использовать fileevent (потому что он должен работать везде).

proc handle_bgexec {callback chan} {
    append ::bgexec_data($chan) [read $chan]
    if {[eof $chan]} {
        # end of file, call the callback
        {*}$callback $::bgexec_data($chan)
        unset ::bgexec_data($chan)
    }
}

proc bgexec {callback args} {
    set chan [open "| $args" r]
    fconfigure $chan -blocking false
    fileevent $chan readable [list handle_bgexec $callback $chan]
    return
}

Вызовите это как bgexec job_done cmd /c start /wait cmd /c make all-all. job_done вызывается с выводом команды после ее завершения.

Для этого также можно использовать потоки, но для этого требуется многопоточная сборка tcl (которая сейчас используется по умолчанию для всех платформ, насколько я знаю, но более старые версии Tcl, особенно под unix, по умолчанию не создают многопоточный Tcl.) и пакет Thread (который включен по умолчанию). Подход к использованию его с потоками будет следующим:

thread::create "[list exec cmd /c start /wait cmd /c make all-all];[list thread::send [thread::id] {callback code}];thread::exit"

Если вам нужно вызывать это на регулярной основе, возможно, стоит использовать только один рабочий поток вместо создания нового для каждого задания.

Изменить: добавьте /wait в качестве параметра для запуска, чтобы первый cmd продолжал работать.

cmd /c start /wait cmd /c make all-all

Вы хотите запустить процесс make в конвейере и использовать цикл событий и fileevent для отслеживания его хода (см. http://wiki.tcl.tk/880)

proc handle_make_output {chan} {
    # The channel is readable; try to read it.
    set status [catch { gets $chan line } result]
    if { $status != 0 } {
        # Error on the channel
        puts "error reading $chan: $result"
        set ::DONE 2
    } elseif { $result >= 0 } {
        # Successfully read the channel
        puts "got: $line"
    } elseif { [chan eof $chan] } {
        # End of file on the channel
        puts "end of file"
        set ::DONE 1
    } elseif { [chan blocked $chan] } {
        # Read blocked.  Just return
    } else {
        # Something else
        puts "can't happen"
        set ::DONE 3
    }
}

set chan [open "|make" r]
chan configure $chan -blocking false
chan event $chan readable [list handle_make_output $chan]
vwait ::DONE
close $chan

Я не уверен в использовании vwait в цикле событий Tk. Возможно, здесь мне поможет специалист.