Мультиметоды Clojure, как добавить данные?

Неудачный ответ, как упомянули @Arthur и @noahz, заключается в том, что иерархии нельзя описать с помощью классов. Что же остается нам с мультиметодами?

Лучшим ответом может быть включение ключа :type в простые карты и отправка по этому значению. Вы теряете такие вещи, как автоматически сгенерированный конструктор, предоставляемый протоколами, но это очень простое решение, предлагающее большую гибкость.

(def sword {:type ::weapon, :name "sword", :damage 10})
(def apple {:type ::item, :name "apple"})
(def cupboard {:type ::furniture, :name "cupboard"})
(def bag {:type ::bag, :name "bag"})

(derive ::weapon ::item)
(derive ::container ::item)
(derive ::bag ::container)
(derive ::furniture ::container)

; dispatch on [type-of-src type-of-dst]
(defmulti putin (fn [src dst] [(src :type) (dst :type)]))
(defmethod putin [::item ::container] [src dst] :success_0)

(println (putin sword bag)) ; :success_0

Альтернативой, хотя и слишком сложной, является создание карты классов для ключевых слов и использование ее для поиска ключевых слов в иерархии при диспетчеризации. Опять же, я подчеркну, что вы, вероятно, можете найти что-то лучше, но вариант есть.

; used to look up the keywords associated with classes
(def class-keyword-map (atom {}))

; get the keyword associated with an instance's class
(defn class-keyword
  [instance]
  (@class-keyword-map (class instance)))

; this macro defines a record as normal
; however, after defining the record,
; it associates the record's type with
; a keyword generated by the record name
(defmacro def-adventure-record
  [clazz & body]
  `(do
     ; create the record as normal
     (defrecord ~clazz ~@body)
     ; and add the type to the keyword lookup
     (swap!
       class-keyword-map
       assoc ~clazz (keyword (str *ns*) (str '~clazz)))))

(def-adventure-record Item [name])
(def-adventure-record Weapon [name, damage])
(def-adventure-record Furniture [name])
(def-adventure-record Container [name])
(def-adventure-record Bag [name])

; we still need to use keywords,
; but at this point, they've been
; generated for us by the macro above
(derive ::Weapon ::Item)
(derive ::Container ::Item)
(derive ::Bag ::Container)
(derive ::Furniture ::Container)

(def sword (Weapon. "sword" 10))
(def apple (Item. "apple"))
(def cupboard (Furniture. "cupboard"))
(def bag (Bag. "bag"))

; this dispatch is done on the class's keywords
(defmulti putin (fn [src dst] [(class-keyword src) (class-keyword dst)]))

; again, keywords describe the multimethod
(defmethod putin [::Item ::Container] [src dst] :success_0)

(println (putin sword bag)) ; :success_0

Вы хотите перенести систему типов Java в Clojure. Это можно сделать (в соответствии с вашими предпочтениями) с помощью протоколов (см. также http://clojure.org/protocols)

Тем не менее, я рекомендую вам прочитать следующую запись в блоге: Ориентированное программирование на Clojure. Подумайте, возможно, что структуры данных, возможно, достаточно хороши (и более гибки), чем использование типов.

Clojure предлагает как протоколы, так и мультиметоды для решения такого рода проблем. Если вы хотите использовать дезапись, я бы рекомендовал вместо этого использовать протоколы.

конкретная проблема объясняется на странице с несколькими методами:

«Вы также можете использовать класс в качестве дочернего (но не родительского, единственный способ сделать что-то дочерним для класса — через наследование Java)».

(derive java.util.Map ::collection)
(derive java.util.Collection ::collection)

Вы можете продолжать использовать isa? иерархии с