Импорт данных файла журнала в приложение

Не уверен, в чем ваша проблема, но вот несколько указателей на ваш оператор Switch и другой код.

Насколько я знаю, функция/модуль use Switch была заменена в perl v5.10.1 на given/when, и теперь она устарела. Лично я всегда находил эти утверждения немного странными и ненадежными. И ни в коем случае не незаменимым, поскольку perl такой гибкий язык.

В вашем случае я бы порекомендовал вместо этого поиск по хешу:

my %camp = ("ssss_uk_01B" => 1,
            "ssss_uk_01C" => 2,
            ...);
my %cand = ("Brown"       => 1,
            "Cameron"     => 2,
            ...);

$campaign_id  = $camp{$campaign};
$candidate_id = $cand{$choice}

Если вам нужно указать значения по умолчанию, вы можете использовать оператор присваивания defined-or :

$campaign_id //= "default value here";

Ваши substr задания немного неверны. Во-первых, вы используете все четыре аргумента, которые в perldoc описываются так:

substr EXPR,OFFSET,LENGTH,REPLACEMENT

Это означает, что вы заменяете свое совпадение на '' пустую строку. Это влияет на саму переменную и удалит нужные данные, если их оставить отдельно. Длина в вашем случае также не нужна, так как это конец строки, которую вы ищете. Наконец, вас спасает тот факт, что вы используете возвращаемое значение оператора substr.

Наконец, когда я пробую ваши задания, я получаю одноразовую ошибку в вашем первом задании ($campaign). Вывод :ssss_uk_01, а вы ожидаете ssss_uk_01.

Чтобы правильно использовать функцию substr, вы должны использовать:

$campaign = substr $campaign, 9;
$validity = substr $validity, 9;
$choice   = substr $choice, 7;

Я согласен с предложением TLP об использовании хэшей для поисковых таблиц. Но в реальном приложении эти таблицы поиска должны быть заполнены поиском в базе данных, чтобы избежать необходимости изменять приложение при изменении данных в других таблицах.

Я также склонен меньше доверять формату данных в журнале. Использование разделения избавляет от необходимости знать точную длину метки + размер двоеточия. В связи с этим я также предлагаю нормализовать данные, прежде чем использовать их в качестве ключа в хеше поиска. В этом примере я просто сделал все в нижнем регистре.

Пока вы используете предупреждения, вы также можете использовать функцию предупреждения, чтобы сообщить об ошибках. В реальном приложении вы можете отправлять предупреждения в систему оповещения по электронной почте, чтобы всегда знать, когда у вашего автоматического программного обеспечения возникают проблемы.

Идиома or+die — отличная практика при работе с файлами. Но это будет более информативно, когда эти штампы появятся, если вы включите $OS_ERROR (a.k.a. $!), даже для печати. Таким образом, вы будете знать разницу между отказом в разрешении, несуществующим или заполненным диском и т. д.

Это предложения, которые говорят о проблемах написания поддерживаемых и устойчивых программ. Но я лично считаю, что эстетика кода также способствует ремонтопригодности. Значимые соглашения об именах и форматирование кода могут иметь большое значение, когда вы откроете эту программу через год или два, чтобы внести улучшения или исправить ошибку. Я предпочитаю создавать код, в котором отсутствует ненужный беспорядок, такой как комментарии, констатирующие очевидное, или использование комментариев для удаления блоков кода.

Продолжайте хорошую работу. Мир нуждается в большей автоматизации программного обеспечения.

#!/usr/bin/perl

use strict;
use warnings;
use DBI;

#
# _voting.pl
#
my $logfile = '/var/www/voting/votes.txt';

my $errors = 0;

my %campaign_id_for = (
    'ssss_uk_01b' => 1,
    'ssss_uk_01c' => 2,
    'ssss_uk_01d' => 3,
    'ssss_uk_01e' => 4,
    'ssss_uk_01f' => 5,
    'ssss_uk_01g' => 6,
);

my %candidate_id_for = (
    'brown'   => 1,
    'cameron' => 2,
    'balls'   => 3,
    'green'   => 4,
    'boring'  => 5,
    'tupele'  => 6,
);

my $dbh = DBI->connect( 
    'DBI:mysql:database=sms_voting;host=localhost',
    'sisisi', 
    '*********', 
    { 'RaiseError' => 1 } 
);

my $sth = $dbh->prepare(q{
    INSERT INTO voting (
        epoch,
        validity,
        choice,
        campaigns_id,
        candidates_id
    ) VALUES (
        ?,
        ?,
        ?,
        ?,
        ?
    )
});

my $fh;

open $fh, '<', $logfile
    or die "open $logfile: $!";

LINE:
for my $line (<$fh>) {

    my ($vote, $epoch,  $campaign, $validity, $choice,
        $CONN, $MSISDN, $GUID,     $Shortcode
    ) = split /\s+/, $line;

    ($campaign) = reverse split /:/, $campaign;
    ($validity) = reverse split /:/, $validity;
    ($choice)   = reverse split /:/, $choice;

    my $campaign_id  = $campaign_id_for{ lc $campaign };
    my $candidate_id = $candidate_id_for{ lc $choice };

    if ( $epoch && $validity && $choice && $campaign_id && $candidate_id ) {

        $sth->execute(
            $epoch,
            $validity,
            $choice,
            $campaign_id,
            $candidate_id
        );

        print "$epoch $validity $choice\n"
            or die "print: $!";

        next LINE;
    }
    else {

        warn "failed to parse: $line\n";
        $errors++;
    }
}

close $fh
    or die "close $logfile: $!";

# debug
print "error count: $errors\n"
    or die "print: $!";