динамически создавать формы с помощью STRING

Объявите переменную NewForm как TForm:

var
  NewForm: TForm;
begin
  NewForm := TMyForm.Create(Tab1); //compiles OK
  NewForm := TMyOtherForm.Create(Tab2); //also compiles OK
end;

Я предполагаю, что TMyForm и TMyOtherForm являются производными от TForm.

СУХОЙ

Вы также можете сократить повторяющийся код, используя переменную ссылки на класс, например:

procedure TForm1.ShowFormOnTab(pProcName:String);
var
  NewForm: TForm;
  ClassToUse: TFormClass;
  NewTab: TTabSheet;
  FormName: String;

begin
  NewTab := TTabSheet.Create(PageControl1);
  NewTab.PageControl:= PageControl1;
  NewTab.Caption:='hi';
  PageControl1.ActivePage :=  NewTab;

  if pProcName='ProcfrmSetupItemCategories' then
    ClassToUse := TfrmSetupItemCategories
  else if pProcName='ProcfrmZones' then
    ClassToUse := TfrmZones
  else
    ClassToUse := nil;
  if Assigned(ClassToUse) then
  begin
    NewForm := ClassTouse.Create(NewTab);
    NewTab.Caption := NewForm.Caption;
    //if you access custom properties or methods, this is the way:
    if NewForm is TfrmZones then
      TfrmZones(NewForm).ZoneInfo := 'MyInfo';
  end;
end;

Зарегистрируйте свои классы, а затем создайте формы из строки

Как указывает сэр Руфо в своем комментарии, вы даже можете продолжить регистрацию своих классов (я не уверен, что это можно сделать в Lazarus, это упражнение на ваше усмотрение).

Во-первых, зарегистрируйте классы форм, которые вы хотите создать, из имени класса перед любым вызовом вашего метода ShowFormOnTab, например:

procedure TMainForm.FormCreate(Sender: TObject);
begin
  RegisterClass(TfrmSetupItemCategories);
  RegisterClass(TfrmZones);
  //and other classes
end;

Затем вы можете изменить код, чтобы получить ссылку на класс из строки имени класса:

procedure TForm1.ShowFormOnTab(pProcName:String);
var
  NewForm: TForm;
  ClassToUse: TFormClass;
  ClassNameToUse: string;
  NewTab: TTabSheet;
  FormName: String;

begin
  NewTab := TTabSheet.Create(PageControl1);
  NewTab.PageControl:= PageControl1;
  NewTab.Caption:='hi';
  PageControl1.ActivePage :=  NewTab;
  //get rid of 'Proc' and add the T
  //or even better, pass directly the class name
  ClassNameToUse := 'T' + Copy(pProcName, 5, MaxInt);
  ClassToUse := TFormClass(FindClass(ClassNameToUse));

  if Assigned(ClassToUse) then
  begin
    NewForm := ClassTouse.Create(NewTab);
    NewTab.Caption := NewForm.Caption;
    //if you access custom properties or methods, this is the way:
    if NewForm is TfrmZones then
      TfrmZones(NewForm).ZoneInfo := 'MyInfo';
  end;
end;

Таким образом, код остается одинаковым для любого количества классов.

Дополнительные сведения об этом см. в разделе Создание формы Delphi из строки в delphi.about. ком.

Объявите свою переменную как тип предка:

var
  NewForm: TForm;

or

var
  NewForm: TCustomForm;

Недостаток: вам нужно будет привести переменную к определенному классу, если вы хотите вызвать любые методы вашей формы, которые вы объявили сами.

Используйте «мягкое» приведение, если вы хотите, чтобы компилятор проверял, что NewForm на самом деле является TMyForm во время выполнения:

(NewForm as TMyForm).MyMethod;

Когда вы абсолютно уверены, что NewForm является TMyForm (например, когда вы только что создали его), вы также можете использовать «жесткое» приведение:

TMyForm(NewForm).MyMethod;

С зарегистрированными классами при инициализации используемых форм вы можете сократить его до

Function CreateAndDock(pc:TPageControl;const FormName:String):Boolean;
begin
  Result := false;
  if Assigned(GetClass(FormName)) and GetClass(FormName).InheritsFrom(TCustomForm)   then
  With TFormClass( GetClass(FormName)).Create(pc.Owner) do
    begin
     ManualDock(pc);
     Show;
     Result := true;
    end;
end;

procedure TForm4.Button1Click(Sender: TObject);
begin
   ShowMessage(IntToStr(Integer(CreateAndDock(pagecontrol1,'TDockForm'))));
   ShowMessage(IntToStr(Integer(CreateAndDock(pagecontrol1,'TNotExists'))));
end;