Для нового проекта я рассматриваю возможность использования объектно-ориентированных функций Fortran2003. Одна вещь, которую я пробовал, связана с указателем процедуры, который указывает на функцию (не подпрограмму), которая возвращает указатель на полиморфный тип. Мне интересно, законна ли такая конструкция, поскольку я получаю смешанные результаты от разных компиляторов (см. Ниже).
В качестве конкретного примера рассмотрим следующий интерфейс функции:
abstract interface
function if_new_test(lbls) result(t)
import :: test_t
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
end function if_new_test
end interface
И код использования должен иметь указатель на процедуру, который может указывать на функции с этим интерфейсом:
procedure(if_new_test),pointer :: nt
Я спрашиваю, законно ли это, потому что gfortran (4.7.2) жалуется на объявление указателя процедуры с сообщением:
Ошибка: переменная CLASS 'nt' в (1) должна быть фиктивной, доступной для размещения или указателем.
Я не понимаю этого сообщения об ошибке, поскольку nt
сам по себе является указателем, а функция, на которую он указывает, также является указателем.
Для справки следует полный исходный код примера. Во-первых, модуль, содержащий мои производные типы, интерфейсы и функции / подпрограммы:
module test_m
implicit none
type :: test_t
character(len=10) :: label
contains
procedure :: print => print_test
end type test_t
type,extends(test_t) :: test2_t
character(len=10) :: label2
contains
procedure :: print => print_test2
end type test2_t
abstract interface
function if_new_test(lbls) result(t)
import :: test_t
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
end function if_new_test
subroutine if_make_test(t,lbls)
import :: test_t
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
end subroutine if_make_test
end interface
contains
subroutine print_test(self)
implicit none
class(test_t),intent(in) :: self
print *, self%label
end subroutine print_test
subroutine print_test2(self)
implicit none
class(test2_t),intent(in) :: self
print *, self%label, self%label2
end subroutine print_test2
function new_test(lbls) result(t)
implicit none
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
call make_test(t,lbls)
end function new_test
function new_test2(lbls) result(t)
implicit none
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
call make_test2(t,lbls)
end function new_test2
subroutine make_test(t,lbls)
implicit none
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
allocate(test_t::t)
t%label = lbls(1)
end subroutine make_test
subroutine make_test2(t,lbls)
implicit none
class(test_t),pointer :: t
character(len=*),intent(in) :: lbls(:)
allocate(test2_t::t)
select type(t) ! so the compiler knows the actual type
type is(test2_t)
t%label = lbls(1)
t%label2 = lbls(2)
class default
stop 1
end select
end subroutine make_test2
end module test_m
И основная программа, использующая этот модуль:
program test
use test_m
implicit none
class(test_t),pointer :: p
procedure(if_make_test),pointer :: mt
procedure(if_new_test),pointer :: nt
mt => make_test
call mt(p,["foo"])
call p%print
deallocate(p)
mt => make_test2
call mt(p,["bar","baz"])
call p%print
deallocate(p)
p => new_test(["foo"])
call p%print
deallocate(p)
p => new_test2(["bar","baz"])
call p%print
deallocate(p)
nt => new_test
p => nt(["foo"])
call p%print
deallocate(p)
nt => new_test2
p => nt(["bar","baz"])
call p%print
deallocate(p)
end program test
Программа сначала создает объекты с помощью подпрограмм make_test
и make_test2
, и в моем тестировании это работает со всеми компиляторами, которые я пробовал. Затем объекты создаются путем прямого вызова функций new_test
и new_test2
, что также работает в моих тестах. Наконец, объекты должны снова создаваться с помощью этих функций, но косвенно через указатель процедуры nt
.
Как указано выше, gfortran (4.7.2) не компилирует объявление nt
.
ifort (12.0.4.191) выдает внутреннюю ошибку компилятора в строке nt => new_test
.
pgfortran (12.9) компилируется без предупреждения, и исполняемый файл дает ожидаемые результаты.
Итак, является ли то, что я пытаюсь сделать незаконным, согласно Fortran2003, или компилятор все еще недостаточно поддерживает такие функции? Должен ли я просто использовать подпрограммы вместо функций (поскольку это, кажется, работает)?