dll Delphi-to-C: передача массивов

Ваш вопрос содержит два объявления Delphi для внешней функции. Один из них использует TArray<T> в качестве параметра. Это совершенно неправильно. Не делай этого. Вы не можете использовать динамический массив Delphi в качестве типа взаимодействия. Причина в том, что TArray<T> — это сложный управляемый тип, который может быть создан и использован только кодом Delphi.

Вам нужно сделать то, что я делаю ниже, и как я объяснил в своем ответе на ваш предыдущий вопрос, и объявить параметр массива как указатель на тип элемента. Например, PInteger, PDouble и т. д.

Здесь довольно много путаницы и ненужной сложности. Вам нужен простейший возможный пример, показывающий, как передать массив из вашего кода Delphi в код C.

Вот.

Код C

//testarray.c

void printDouble(double d); // linker will resolve this from the Delphi code

void test(double *arr, int count)
{
    int i;
    for (i=0; i<count; i++)
    {
        printDouble(arr[i]);
    }
}

Код Delphi

program DelphiToC;

{$APPTYPE CONSOLE}

uses
  Crtl;

procedure _printDouble(d: Double); cdecl;
begin
  Writeln(d);
end;

procedure test(arr: PDouble; count: Integer); cdecl; external name '_test';

{$L testarray.obj}

var
  arr: TArray<Double>;

begin
  arr := TArray<Double>.Create(1.0, 2.0, 3.0, 42.0, 666.0);
  test(PDouble(arr), Length(arr));
  Readln;
end.

Скомпилируйте код C, используя, например, компилятор Borland C следующим образом:

bcc32 -c testarray.c

И вывод:

 1.00000000000000E+0000
 2.00000000000000E+0000
 3.00000000000000E+0000
 4.20000000000000E+0001
 6.66000000000000E+0002

Обратите внимание, что я связался с кодом C статически, потому что это было проще для меня. Ничего особенного не изменится, если вы поместите код C в DLL.

Вывод таков, что код, который я дал вам в своем ответе на ваш предыдущий и который я повторяю здесь, является правильным. Этот подход успешно передает массив из кода Delphi в C. Похоже, ваша диагностика и отладка ошибочны.

Вы проверяете только A[0], поэтому неудивительно, что вы видите только одно значение. Если бы вы только посмотрели на A[1], A[2], ..., A[n-1], вы бы увидели, что все значения передаются правильно. Или, возможно, ваша отладка проводилась по ошибочному объявлению внешней функции, которая использовала TArray<T> в качестве параметра.