уникально переименовать каждый из многих файлов, используя perl

Здесь:

#!/usr/bin/perl
use warnings;
use strict;

use autodie;
use File::Copy;

# capture script name, in case we are running the script from the 
# same directory we working on. 
my $this_file = (split(/\//, $0))[-1];
print "skipping file: $this_file\n";

my $oldnames = "/some/path/to/oldnames";
my $newnames = "/some/path/to/newnames";

# open the directory
opendir(my $dh, $oldnames); 

# grep out all directories and possibly this script. 
my @files_to_rename = grep { !-d && $_ ne $this_file } readdir $dh;
closedir $dh;

### UPDATED ###
# create hash of file names from lists:
my @old_filenames = qw(file1 file2 file3 file4);
my @new_filenames = qw(onefile twofile threefile fourfile);
my $filenames = create_hash_of_filenames(\@old_filenames, \@new_filenames);
my @missing_new_file = ();  


# change directory, so we don't have to worry about pathing
# of files to rename and move... 
chdir($oldnames);
mkdir($newnames) if !-e $newnames;


### UPDATED ###
for my $file (@files_to_rename) {
    # Check that current file exists in the hash,
    # if true, copy old file to new location with new name
    if( exists($filenames->{$file}) ) { 
        copy($file, "$newnames/$filenames->{$file}");
    } else {
        push @missing_new_file, $file;
    } 
}


if( @missing_new_file ) { 
    print "Could not map files:\n", 
        join("\n", @missing_new_file), "\n";
}

# create_hash_of_filenames: creates a hash, where
# key = oldname, value = newname
# input: two array refs 
# output: hash ref 
sub create_hash_of_filenames {
    my ($oldnames, $newnames) = @_; 
    my %filenames = (); 

    for my $i ( 0 .. (scalar(@$oldnames) - 1) ) { 
        $filenames{$$oldnames[$i]} = $$newnames[$i];
    }

    # see Dumper output below, to see data structure
    return \%filenames;
}

Результат самосвала:

$VAR1 = {
  'file2' => 'twofile',
  'file1' => 'onefile',
  'file4' => 'fourfile',
  'file3' => 'threefile'
};

Запуск скрипта:

$ ./test.pl 
skipping file: test.pl
Could not map files:
a_file.txt
b_file.txt
c_file.txt

Результат файла:

$ ls oldnames/
a_file.txt
b_file.txt
c_file.txt
file1
file2
file3
file4

$ ls newnames/
fourfile
onefile
threefile
twofile

Ваш код немного странный, но он должен работать. Вы запускаете его в каталоге «oldnames» или в каталоге над ним? Вы должны быть в каталоге над ним. Более стандартный способ записи будет таким:

#!/usr/bin/perl -w
use strict; use warnings;

my $dir = 'oldnames';
opendir ( my $oldnames, $dir) or die "cannot open dir $dir: $!";
my @file = readdir $oldnames;
closedir $oldnames;

print "@file\n";

Это заполнит @files всеми файлами в oldnames, включая '.' и '..'. Возможно, вам придется отфильтровать их в зависимости от того, как вы выполняете переименование.

Можно ли сделать это с помощью rename? Это позволяет вам использовать perl код и выражения в качестве аргументов, насколько я помню.

Настоящий ответ - это ответ @chrsblck, он выполняет некоторые проверки и не создает беспорядка.

Для сравнения вот грязный лайнер, которого может хватить. Он зависит от того, предоставите ли вы список эквивалентных новых имен файлов, которые переименуют ваш список старых файлов в правильном порядке. Возможно, в вашей ситуации (когда вы не хотите программно преобразовывать имена файлов) вы могли бы просто использовать цикл оболочки (см. конец этого поста), читая списки новых и старых имен из файла. Лучшим perl решением было бы поместить оба из этих списков имен файлов в два столбца, а затем этот файл с помощью переключателя -a , @F и затем использоватьFile::Copy для копирования файлов.

В любом случае, ниже приведены некоторые предложения.

Сначала настройте вещи:

 % vim newfilenames.txt # list new names one per line corresponding to old names.
 % wc -l newfilenames.txt # the same number of new names as files in ./oldfiles/
  8 newfilenames.txt
 % ls -1 oldfiles  # 8 files rename these in order to list from newfilenames.txt
 newSEACODI-sww2320H-sww24_07A_CP.9_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07B_CP.10_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07C_CP.11_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07D_CP.12_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07E_R.1_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07F_R.3_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07G_R.4_sww2320H_sww2403F.fsa
 newSEACODI-sww2320H-sww24_07H_R.5_sww2320H_sww2403F.fsa

С файлами, расположенными, как указано выше, скопируйте все:

perl -MFile::Copy -E 'opendir($dh , oldfiles); @newfiles=`cat newfilenames.txt`; chomp @newfiles; @oldfiles = sort grep(/^.+\..+$/, readdir $dh); END {for $i (0..$#oldfiles){copy("oldfiles/$oldfiles[$i]", "newfiles/$newfiles[$i]"); }}'

Некрасиво: вам нужно grep и sort на @oldfiles избавиться от . .. и упорядочить элементы массива. И всегда есть риск того, что опечатка может создать беспорядок, и ее будет трудно понять.
Если вы поместите старое и новое имена в пару файлов, вы можете просто сделать это с помощью сценария оболочки:

for i in `cat ../oldfilenames.txt` ; do ; done; for n in `cat ../newfilenames.txt`; do cp $i $n;

или просто cd в директорию со старыми файлами и делаем:

mkdir new
for i in * ; do ; done; for n in `cat ../newfilenames.txt`; do cp $i new/$n;

Удачи!