Простая команда «копировать форму»

Функция sexp-at-point дает вам sexp ("форму") в курсоре. Просто скопируйте это в kill-ring, используя kill-ring-save. Например.:

(defun copy-sexp-at-point ()
  (interactive)
  (let ((bnds  (bounds-of-thing-at-point 'sexp)))
    (kill-ring-save (car bnds) (cdr bnds))))

В качестве альтернативы просто используйте kill-new:

(defun copy-sexp-at-point ()
  (interactive)
  (kill-new (thing-at-point 'sexp)))

Причина, по которой ваш copy-form не может быть привязан к клавише, заключается в том, что это функция, а не команда — в ней отсутствует interactive.

Однако в вашем случае вам даже не нужно писать новую функцию.

Попробуйте комбинацию из

mark-sexp - это интерактивная скомпилированная функция Лиспа в `lisp.el'.

Он связан с C-M-@, C-M-SPC.

а также

M-w запускает команду kill-ring-save, которая представляет собой интерактивную скомпилированную функцию Lisp в `simple.el'.

Он связан с ‹C-insertchar›, M-w, ‹строка меню› ‹редактировать› ‹копировать›.

Я не уверен, что понимаю вопрос, но когда мне нужно сделать то, что я считаю «копированием сбалансированной формы», я делаю: M-C-SPC M-w. Если я хочу его вырезать, я делаю M-C-SPC C-w.

Вот что я обычно использую. Почему-то мне удобнее убить сбалансированное выражение, чем копировать. Если вместо этого мне нужна копия, я сначала убиваю, а потом отменяю.

Эта функция уничтожает строку, если точка находится внутри строки, в противном случае используется сбалансированное выражение, т.е. (),[],{},<> или что-то другое, определенное синтаксисом.

(defun kill-at-point ()
  "Kill the quoted string or the list that includes the point"
  (interactive)
  (let ((p (nth 8 (syntax-ppss))))
    (cond
      ;; string
      ((eq (char-after p) ?\")
       (goto-char p)
       (kill-sexp))
      ;; list
      ((ignore-errors (when (eq (char-after) ?\()
                        (forward-char))
                      (up-list)
                      t)
       (let ((beg (point)))
         (backward-list)
         (kill-region beg (point)))))))

Я также попытался добавить особый случай, когда точка находится внутри комментария, но я не смог найти общий способ определить границы комментария в точке. Если кто-нибудь знает, пожалуйста, скажите мне.

Эта другая функция также может иметь значение. Он метит, а не убивает, как предыдущий. Приятно то, что он расширяет регион каждый раз, когда он вызывается. Я связываю первый с C-,, а второй с C-M-,.

(defun mark-at-point ()
  "Mark the quoted string or the list that includes the point"
  (interactive)
  (let ((p (nth 8 (syntax-ppss))))
    (if (eq (char-after p) ?\")
    (progn
      (goto-char p)
          (set-mark (point))
      (forward-sexp))
      (progn
        (when (eq (char-after) 40)
          (forward-char))
        (condition-case nil
            (progn
              (up-list)
              (set-mark (point))
              (let ((beg (point)))
                (backward-list)
                (exchange-point-and-mark)))
          (error
           (when (looking-back "}")
             (exchange-point-and-mark)
             ;; assumes functions are separated by one empty line
             (re-search-backward "^[^A-Z-a-z]" nil t)
             (forward-char))))))))