Как работает интеллектуальное завершение кода в Scheme?

Я сделал для вас стартовый код. Это для Emacs Lisp, но его должно быть очень легко перенести на Scheme.

Вот ваш пример использования:

(defun create-object ()
  (lexical-let* ((val 0)
                 (get (lambda() val))
                 (set (lambda(x) (setq val x))))
    (generate-dispatch-table get set)))

(setq obj (create-object))
(funcall (funcall obj 'get))
;; => 0
(funcall (funcall obj 'set) 1)
;; => 1
(funcall (funcall obj 'get))
;; => 1
(scheme-completions obj)
;; => (get set)

И вот как это реализовано:

(defmacro generate-dispatch-table (&rest members)
  `(lambda (method)
     (cond ,@(mapcar
               (lambda (x) `((eq method ',x) ,x)) members))))

(defun collect (pred x)
  (when (and x (listp x))
    (let ((y (funcall pred x))
          (z (append
              (collect pred (car x))
              (collect pred (cdr x)))))
      (if y
          (append (list y) z)
        z)))) 

(defun scheme-completions (obj)
  (collect
   (lambda(x) (and (eq (car x) 'eq)
              (eq (cadr x) 'method)
              (eq (caaddr x) 'quote)
              (cadr (caddr x))))
   obj))

А вот и простой визуальный интерфейс для доработок:

(require 'helm)
(defun scheme-completions-helm ()
  (interactive)
  (let ((y (and
               (looking-back "(funcall \\([^ ]*\\) +")
               (intern-soft (match-string 1)))))
    (when y
      (helm :sources
            `((name . "members")
              (candidates . ,(scheme-completions (eval y)))
              (action . (lambda(x) (insert "'" x)))))))) 

Я не пользователь Emacs, но использую DrRacket, и у него есть объектная система, и он делает то, что должна делать IDE, но я знаю, что Emacs очень настраиваемый, поскольку он использует elisp, поэтому вы можете поддерживать свой собственный синтаксис как при подсветке синтаксиса. и завершение табуляции. Итак, вы делаете:

1. Создайте свою собственную систему объектов
2. Отредактируйте свой редактор Emacs, чтобы делать то, что вы хотите

Многие мои коллеги используют его и таким образом исправляют свой Emacs.

Еще один момент: этот вопрос заставляет меня задуматься об ресурсах на Schemewiki.org по этому вопросу. где упоминаются различные подходы, и даже в качестве примера публикуется код, аналогичный тому, который вы опубликовали. Это хорошее чтение.

Я бы избегал двойного представления символов в create-object через obarray. Кроме того, интерфейс объекта — это все функции. Поэтому используйте fset и избегайте двойного funcall.

(defun create-object ()
  (lexical-let (val
        (_oa (make-vector 11 0)))
    (fset (intern "get" _oa) (lambda () val))
    (fset (intern "inc" _oa) (lambda () (incf val)))
    (fset (intern "set" _oa) (lambda (new-val) (setq val new-val)))
    (lambda (method &rest args)
      (apply 'funcall (intern (symbol-name method) _oa) args))))


(fset 'obj1 (create-object))
(fset 'obj2 (create-object))

(obj1 'set 1)
(obj2 'set 2)

(obj1 'inc)
(obj2 'inc)
(obj2 'inc)

(obj2 'get)
(obj1 'get)

Пример для наследования:

(defun create-object ()
  (lexical-let (val
        (_oa (make-vector 11 0)))
    (fset (intern "get" _oa) (lambda () val))
    (fset (intern "inc" _oa) (lambda () (incf val)))
    (fset (intern "set" _oa) (lambda (new-val) (setq val new-val)))
    (lambda (method &rest args)
      (apply 'funcall (or (intern-soft (symbol-name method) _oa)
              (error "Undefined function: %s" method))
         args))))


(defun create-object-add10 ()
  (lexical-let ((base (create-object))
        (_oa (make-vector 11 0)))
    (fset (intern "inc" _oa) (lambda () (funcall base 'set (+ (funcall base 'get) 10))))
    (lambda (method &rest args)
      (let ((call (intern-soft (symbol-name method) _oa)))
    (if call
        (apply 'funcall call args)
      (apply 'funcall base method args))))))

(fset 'obj1 (create-object))
(fset 'obj2 (create-object-add10))

(obj1 'set 1)
(obj2 'set 2)

(obj1 'inc)
(obj2 'inc)
(obj2 'inc)

(obj2 'get)
(obj1 'get)

Определение create-object-подобных методов должно дополнительно поддерживаться через макросы. Здесь этого не делают.

Для получения дополнительных возможностей обратите внимание, что в emacs есть CLOS-совместимая объектно-ориентированная система:

https://www.gnu.org/software/emacs/manual/html_node/eieio/index.html