цикл for с несколькими переменными (массивами) для изменения каждого запуска

Другой!

@echo off
setlocal EnableDelayedExpansion
set LF=^


rem ** Previous two empty lines required
set "vars=1,10,a,x;2,20,b,y;3,30,c,x;4,40,d,y;5,50,e,x;6,60,f,y;7,70,g,x;8,80,h,y;9,90,i,x"
for /F "tokens=1-4 delims=," %%A in ("%vars:;=!LF!%") do echo command /S %%A -subswitch %%B /H %%C -o %%D

Выход:

command /S 1 -subswitch 10 /H a -o x
command /S 2 -subswitch 20 /H b -o y
command /S 3 -subswitch 30 /H c -o x
command /S 4 -subswitch 40 /H d -o y
command /S 5 -subswitch 50 /H e -o x
command /S 6 -subswitch 60 /H f -o y
command /S 7 -subswitch 70 /H g -o x
command /S 8 -subswitch 80 /H h -o y
command /S 9 -subswitch 90 /H i -o x

EDIT: Добавлен новый метод в ответ на комментарии

Предыдущий пакетный файл — самый простой способ решить эту проблему. Однако, если вы хотите «сохранить определение массива в удобочитаемом виде для других коллег», то метод, описанный ниже, может быть более понятным. Эта программа также решает вашу проблему «включить тест, который проверяет, действительно ли у вас есть 4 вары»:

@echo off
setlocal

rem Define the *array* of variables per run
set run[1]=1,10,a,x
set run[2]=2,20,b,y
set run[3]=3,30,c,x
set run[4]=4,40,d,y
set run[5]=5,50,e,x
set run[6]=6,60,f
set run[7]=7,70,g,x
set run[8]=8,80,h,y
set run[9]=9,90,i,x

for /F "tokens=1-5 delims==," %%A in ('set run[') do (
   if "%%E" neq "" (
      ECHO command /S %%B -subswitch %%C /H %%D -o %%E
   ) else (
      echo ERROR: Missing variable in %%A
   )
)

Выход:

command /S 1 -subswitch 10 /H a -o x
command /S 2 -subswitch 20 /H b -o y
command /S 3 -subswitch 30 /H c -o x
command /S 4 -subswitch 40 /H d -o y
command /S 5 -subswitch 50 /H e -o x
ERROR: Missing variable in run[6]
command /S 7 -subswitch 70 /H g -o x
command /S 8 -subswitch 80 /H h -o y
command /S 9 -subswitch 90 /H i -o x

@ECHO OFF
SETLOCAL
for %%r in (  "run1:1,10,a,x",
             "run2:2,20,b,y",
             "run3:3,30,c,x",
             "run4:4,40,d,y",
             "run5:5,50,e,x",
             "run6:6,60,f,y",
             "run7:7,70,g,x",
             "run8:8,80,h,y",
             "run9:9,90,i,x"
 ) DO (
 for /f "tokens=2delims=:" %%i in ("%%~r") do (
  echo %%i
 )
)
GOTO :EOF

должен произвести результат, который вы просили.

@echo off

for %%i in (
    "1,10,a,x"
    "2,20,b,y"
    "3,30,c,x"
    "4,40,d,y" 
    "5,50,e,x" 
    "6,60,f,y" 
    "7,70,g,x" 
    "8,80,h,y" 
    "9,90,i,x"
) do for /f "delims=, tokens=1-4" %%A in ("%%~i") do (
    echo %%A %%B %%C %%D
)

от %%A до %%D могут соответствовать вашим номерам от %var1% до %var4%.

Дайте мне знать, если вам нужно что-нибудь объяснить.