Как мне получить доступ к константе в Perl, имя которой содержится в переменной?

Константы, определенные constant.pm, являются просто подпрограммами. Вы можете использовать синтаксис вызова метода, если у вас есть имя константы в строке:

#!/usr/bin/perl -l

use strict; use warnings;
use constant C1 => 111;
use constant C2 => 222;

print __PACKAGE__->$_ for qw( C1 C2 );
# or print main->$_ for qw( C1 C2 );

Таким образом, если вы попытаетесь использовать константу, которая не определена, вы получите ошибку.

«Константы» Perl на самом деле являются подпрограммами, которые возвращают постоянное значение. Компилятор Perl может заменить их соответствующим значением во время компиляции. Однако, поскольку вы хотите получить значение на основе поиска имени во время выполнения, вы должны сделать:

&{$which_constant}();

(И, конечно же, вам нужно где-то no strict 'refs'.)

Предложение Синана использовать семантику вызова метода для обхода ограничений strict 'refs' является самым чистым и простым для чтения решением.

Меня беспокоило только то, что штраф за скорость за использование этого подхода может быть проблемой. Мы все слышали о снижении производительности при вызове метода и преимуществах скорости встроенных функций.

Поэтому я решил запустить тест (код и результаты следуют).

Результаты показывают, что обычные встроенные константы выполняются примерно в два раза быстрее, чем вызовы методов с литеральными именами подпрограмм, и почти в три раза быстрее, чем вызовы методов с переменными именами подпрограмм. Самый медленный подход — это стандартная разблокировка и вызов no strict "refs";.

Но даже самый медленный подход чертовски быстр — более 1,4 миллиона раз в секунду в моей системе.

Эти бенчмарки стирают мою единственную оговорку относительно использования метода вызова метода для решения этой проблемы.

use strict;
use warnings;

use Benchmark qw(cmpthese);

my $class = 'MyConstant';
my $name  = 'VALUE';
my $full_name = $class.'::'.$name;


cmpthese( 10_000_000, {
    'Normal'      => \&normal_constant,
    'Deref'       => \&direct_deref,
    'Deref_Amp'   => \&direct_deref_with_amp,
    'Lit_P_Lit_N' => \&method_lit_pkg_lit_name,
    'Lit_P_Var_N' => \&method_lit_pkg_var_name,
    'Var_P_Lit_N' => \&method_var_pkg_lit_name,
    'Var_P_Var_N' => \&method_var_pkg_var_name,
});

sub method_lit_pkg_lit_name {
    return 7 + MyConstant->VALUE;
}

sub method_lit_pkg_var_name {
    return 7 + MyConstant->$name;
}

sub method_var_pkg_lit_name {
    return 7 + $class->VALUE;
}

sub method_var_pkg_var_name {
    return 7 + $class->$name;
}

sub direct_deref {
    no strict 'refs';
    return 7 + $full_name->();
}

sub direct_deref_with_amp {
    no strict 'refs';
    return 7 + &$full_name;
}

sub normal_constant {
    return 7 + MyConstant::VALUE();
}

BEGIN {
    package MyConstant;

    use constant VALUE => 32;
}

И результаты:

                 Rate Deref_Amp Deref Var_P_Var_N Lit_P_Var_N Lit_P_Lit_N Var_P_Lit_N Normal
Deref_Amp   1431639/s        --   -0%         -9%        -10%        -29%        -35%   -67%
Deref       1438435/s        0%    --         -9%        -10%        -28%        -35%   -67%
Var_P_Var_N 1572574/s       10%    9%          --         -1%        -22%        -29%   -64%
Lit_P_Var_N 1592103/s       11%   11%          1%          --        -21%        -28%   -63%
Lit_P_Lit_N 2006421/s       40%   39%         28%         26%          --         -9%   -54%
Var_P_Lit_N 2214349/s       55%   54%         41%         39%         10%          --   -49%
Normal      4353505/s      204%  203%        177%        173%        117%         97%     --

Результаты, полученные с помощью ActivePerl 826 в Windows XP, YMMV.