У меня есть регулярное выражение:
/abc(def)ghi(jkl)mno(pqr)/igs
Как мне зафиксировать результаты каждой скобки в 3 разных переменных, по одной для каждой скобки? Прямо сейчас я использую один массив для захвата всех результатов, они выводятся последовательно, но затем мне приходится их анализировать, и список может быть огромным.
@results = ($string =~ /abc(def)ghi(jkl)mno(pqr)/igs);
Ваш вопрос немного неоднозначен для меня, но я думаю, вы хотите сделать что-то вроде этого:
my (@first, @second, @third);
while( my ($first, $second, $third) = $string =~ /abc(def)ghi(jkl)mno(pqr)/igs) {
push @first, $first;
push @second, $second;
push @third, $third;
}
while в этом ответе будет бесконечным, если $string соответствует (из-за контекста списка внутри выражения while).
- person YenForYang; 09.06.2021
Начиная с версии 5.10 вы также можете использовать именованные буферы захвата:
#!/usr/bin/perl
use strict; use warnings;
my %data;
my $s = 'abcdefghijklmnopqr';
if ($s =~ /abc (?<first>def) ghi (?<second>jkl) mno (?<third>pqr)/x ) {
push @{ $data{$_} }, $+{$_} for keys %+;
}
use Data::Dumper;
print Dumper \%data;
Вывод:
$VAR1 = {
'first' => [
'def'
],
'second' => [
'jkl'
],
'third' => [
'pqr'
]
};
Для более ранних версий вы можете использовать следующее, что позволяет избежать добавления строки для каждого захваченного буфера:
#!/usr/bin/perl
use strict; use warnings;
my $s = 'abcdefghijklmnopqr';
my @arrays = \ my(@first, @second, @third);
if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
push @{ $arrays[$_] }, $captured[$_] for 0 .. $#arrays;
}
use Data::Dumper;
print Dumper @arrays;
Вывод:
$VAR1 = [
'def'
];
$VAR2 = [
'jkl'
];
$VAR3 = [
'pqr'
];
Но мне нравится хранить связанные данные в одной структуре данных, поэтому лучше вернуться к использованию хэша. Однако для этого требуется вспомогательный массив:
my %data;
my @keys = qw( first second third );
if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
push @{ $data{$keys[$_]} }, $captured[$_] for 0 .. $#keys;
}
Или, если имена переменных действительно first, second и т. д., или если имена буферов не имеют значения, а имеет значение только порядок, вы можете использовать:
my @data;
if ( my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
push @{ $data[$_] }, $captured[$_] for 0 .. $#captured;
}
$data. :)
- person brian d foy; 22.02.2010
first, second и third, и сохранить эти значения в своих собственных массивах. Сравните с примером Леона Тиммермана ( #2259795" title="как я могу хранить записи из регулярного выражения Perl в отдельные переменные"> stackoverflow.com/questions/2259784/ )
- person Sinan Ünür; 22.02.2010
Альтернативный способ сделать это будет выглядеть как ответ ghostdog74, но с использованием массива, в котором хранятся хэш-ссылки:
my @results;
while( $string =~ /abc(def)ghi(jkl)mno(pqr)/igs) {
my ($key1, $key2, $key3) = ($1, $2, $3);
push @results, {
key1 => $key1,
key2 => $key2,
key3 => $key3,
};
}
# do something with it
foreach my $result (@results) {
print "$result->{key1}, $result->{key2}, $result->{key3}\n";
}
с основным преимуществом использования единой структуры данных и наличием приятного читаемого цикла.
@OP, когда скобки захвачены, вы можете использовать переменные $1, $2 .... это обратные ссылки
$string="zzzabcdefghijklmnopqrsssszzzabcdefghijklmnopqrssss";
while ($string =~ /abc(def)ghi(jkl)mno(pqr)/isg) {
print "$1 $2 $3\n";
}
вывод
$ perl perl.pl
def jkl pqr
def jkl pqr
У вас может быть три разных регулярных выражения, каждое из которых ориентировано на определенные группы. Очевидно, вы хотели бы просто назначить разные группы разным массивам в регулярном выражении, но я думаю, что ваш единственный вариант — разделить регулярное выражение.
