Как освободить память после использования FileRerence?

Удалите прослушиватели событий, прежде чем обнулить объект прослушивания.

Вы можете использовать слабые ссылки, чтобы разрешить удаление слушателей, когда объект собран с мусором.

object.addEventListener( ......, ......., false, 0, true );

например, в вашей функции LoadFile:

        ...
        LoadFile(file);
    }
});
...

должно быть:

        ...
        LoadFile(file);
    }
}, false, 0, true );
...

Или вам придется удалить их вручную.

Для этого вам нужно будет переместить обработчики событий в новые именованные функции.

Также вам понадобится массив для хранения ссылок на слушателей и объекты прослушивания, чтобы иметь возможность удалять слушателей ПОСЛЕ того, как слушатели больше не нужны, и ДО обнуления объекта прослушивания.

ПОЖАЛУЙСТА, ОБРАТИ ВНИМАНИЕ:

Когда вы тестируете его и наблюдаете за текущим использованием памяти, не забудьте принудительно запустить сборщик мусора, когда вы чувствуете, что использование памяти уже должно было снизиться, но этого не произошло.

GC срабатывает, когда хочет, и совсем не обязательно после того, как что-то было обнулено при выгрузке.

Чтобы быть ясным, я говорю только о принудительном использовании GC во время разработки / тестирования.

Даже если вы обнуляете каждую ссылку на объект, он не будет немедленно удален из памяти. Вам также необходимо удалить прослушиватели событий. Кроме того, никогда не используйте «безымянные» функции ... сложнее удалить прослушиватель, когда событие вызывает безымянную функцию. Итак, создайте новую функцию и вызовите ее. Например:

test.contentLoaderInfo.addEventListener(Event.COMPLETE, contentLoaderInfoComplete);
...
function contentLoaderInfoComplete(e:Event){
    test.contentLoaderInfo.removeEventListener(Event.COMPLETE, contentLoaderInfoComplete);
    test.unload();
    test = null;
}

Это очистит память.

Я достиг своей цели, если я так сделал FileReferenceList.fileList[5] = null; (когда "шестой файл" больше не используется) Флэш-память немедленно освобождает этот конкретный FileReference.

Другими словами:

Это не работает:

private var file:FileReference;
...
file = FileReferenceList.fileList[5];
...
file = null;

Но это сработало:

FileReferenceList.fileList[5] = null;

Работал на всех Desktop / Plugins / PepperFlash.

См. Рабочий код:

package {
    import flash.net.FileReferenceList;
    import flash.net.FileReference;
    import flash.net.FileFilter;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.display.Sprite;

    public class Main extends Sprite
    {
        private var listFiles:Array;
        private var allTypes:Array;
        private var fileRef:FileReferenceList;
        private var tmpFile:FileReference;
        private var i:uint=0;
        private var j:uint=0;
        private var timer:uint;
        private var imageTypes:FileFilter;
        private var enable:Boolean;

        public function Main()
        {
            imageTypes   = new FileFilter(
                "Images (*.JPG;*.JPEG;*.JPE;)", "*.jpg; *.jpeg; *.jpe;"
            );
            listFiles   = [];
            allTypes    = [imageTypes];

            eventBrowse(true);
        }

        private function eventBrowse(a:Boolean):void
        {
            enable = a;
            if(a===true) {
                stage.addEventListener(MouseEvent.CLICK, browse);

                fileRef = new FileReferenceList();
                fileRef.addEventListener(Event.SELECT, select);
            } else {
                fileRef.removeEventListener(Event.SELECT, select);
                fileRef = null;

                stage.removeEventListener(MouseEvent.CLICK, browse);
            }
        }

        private function browse(e:MouseEvent):void
        {
            if(enable===true) {
                fileRef.browse(allTypes);
            }
        }

        private function select(e:Event):void
        {
            listFiles = fileRef.fileList;

            eventBrowse(false);

            i=0;
            j=listFiles.length;

            if(j>0) {
                loadNextFile();
            }
        }

        private function loadNextFile():void
        {
            if(!(i<j)) {
                listFiles = null;
                trace("Free memory???");
                trace("--------------");
                trace("listFiles:"+ listFiles);
                trace("allTypes:" + allTypes);
                trace("fileRef:" + fileRef);
                trace("tmpFile:" + tmpFile);
                trace("i:" + i);
                trace("j:" + j);
                trace("timer:" + timer);
                trace("--------------");
                eventBrowse(true);
                return;
            }

            tmpFile = listFiles[i];
            trace("Initiate load:" + tmpFile.name);
            tmpFile.addEventListener(Event.COMPLETE, loadedFile);
            tmpFile.load();
        }

        private function loadedFile(f:Event):void
        {
            trace(listFiles);
            trace("Finished load:" + tmpFile.name);
            tmpFile.removeEventListener(Event.COMPLETE, loadedFile);

            tmpFile = null;
            listFiles[i] = null;

            i++;
            loadNextFile();
        }
    }
}

Проблема заключается в сочетании всего перечисленного выше.

1. Вам необходимо удалить прослушиватели событий вручную. Хотя можно использовать слабые ссылки, лучше, если вы возьмете за привычку отслеживать регистрируемых слушателей и всегда отменять их регистрацию должным образом. Таким образом вы сможете избежать утечек памяти (не совсем утечки памяти, но с аналогичным эффектом), о которых вы не ожидали или не думали.

2. Вы создаете слушателей событий в цикле и повторно используете одну и ту же функцию для их обработки. Если вы это сделаете, вы должны каким-то образом получить ссылку на исходный загрузчик и удалить из него прослушиватель событий. Я понятия не имею, как вы пытались включить ответ Жафура, но если вы повторно использовали ссылку на файл для каждого нового файла, это будет причиной того, что он все еще не работает. Возможно, вы сможете обновить свой пример, приведенный выше, с помощью кода, который у вас есть в настоящее время, чтобы мы могли критиковать дальше.

3. Вы никогда не должны принудительно использовать gc (сборщик мусора), если вам нужно это сделать, у вас есть проблемы в другом месте, которые вы должны решить вместо этого, как упоминалось в san.chez. Принудительный сбор мусора - хороший способ увидеть, что вы слишком быстро создаете слишком много объектов. Если вы видите, что использование памяти сильно снижается после принудительного запуска сборщика мусора, вы, вероятно, сделали это и должны переписать свой код, чтобы более эффективно использовать новые .

Судя по объему памяти, который вы израсходовали при создании тонны маленьких файлов или нескольких очень больших файлов, возможно, вы также можете рассказать нам об этом больше.