Как сохранить строку в потоке в Delphi 7 и восстановить в мобильном приложении в XE6?

Чтобы прочитать строку в кодировке UTF8 в мобильном приложении, вы используете массив байтов и класс TEncoding. Нравится:

function TStreamWrap.ReadString: string;
var
  ByteCount: Longint;
  Bytes: TBytes;
begin
  ByteCount := ReadLongint;
  if ByteCount = 0 then
  begin
    Result := '';
    exit;
  end;

  SetLength(Bytes, ByteCount);
  FStream.Read(Pointer(Bytes)^, ByteCount);
  Result := TEncoding.UTF8.GetString(Bytes);
end;

Этот код делает то, что вам нужно в XE6, но, конечно, этот код не будет компилироваться в Delphi 7, потому что он использует TEncoding. Более того, ваша реализация TStreamWrap.WriteString делает то, что вы хотите в Delphi 7, но не работает в XE6.

Теперь похоже, что вы используете одну и ту же базу кода для версий Delphi 7 и Delphi XE6. Это означает, что вам может потребоваться некоторая условная компиляция для обработки текста, который различается в этих версиях.

Лично я бы сделал это, следуя примеру TEncoding. Вам нужна функция, которая преобразует собственный Delphi string в массив байтов в кодировке UTF-8, и соответствующая функция в обратном направлении.

Итак, давайте рассмотрим функцию преобразования строки в байты. Я не могу вспомнить, есть ли у Delphi 7 TBytes тип. Я подозреваю, что нет. Итак, давайте определим это:

{$IFNDEF UNICODE} // definitely use a better conditional than this in real code
type
  TBytes = array of Byte;
{$ENDIF}

Затем мы можем определить нашу функцию:

function StringToUTF8Bytes(const s: string): TBytes;
{$IFDEF UNICODE}
begin
  Result := TEncoding.UTF8.GetBytes(s);
end;
{$ELSE}
var
  UTF8: UTF8String;
begin
  UTF8 := AnsiToUtf8(s);
  SetLength(Result, Length(UTF8));
  Move(Pointer(UTF8)^, Pointer(Result)^, Length(Result));
end;
{$ENDIF}

Функция в обратном направлении должна быть для вас тривиальной.

Когда у вас есть различия в обработке кодировки текста между двумя инкапсулированными версиями Delphi, вы можете написать условно свободный код в остальной части вашей программы. Например, вы могли бы закодировать WriteString следующим образом:

procedure TStreamWrap.WriteString(const Value: string);
var
  UTF8: TBytes;
  ByteCount: Longint;
begin
  UTF8 := StringToUTF8Bytes(Value);
  ByteCount := Length(UTF8);
  WriteLongint(ByteCount);
  if ByteCount > 0 then
    FStream.WriteBuffer(Pointer(UTF8)^, ByteCount);
end;

Вместо

Utf8 : String;

Использовать

Utf8 : Utf8String;

на клиенте. Тогда преобразование будет автоматическим.

РЕДАКТИРОВАТЬ: поскольку клиент находится на мобильной платформе, а Embarcadero решил исключить 8-битные строки в мобильных компиляторах, вышеуказанное не будет работать в этом конкретном случае. Но в других случаях, когда у вас есть 8-битная строка в кодировке UTF-8, Utf8String можно использовать для беспрепятственного преобразования туда и обратно между строками UTF-8 и Unicode без необходимости использования явных функций преобразования UTF-8. Просто используйте это как

UnicodeStringVariable := Utf8StringVariable;

or

Utf8StringVariable := UnicodeStringVariable;

и компилятор вставит соответствующее преобразование.