Код ошибки времени выполнения VBS 800A01B6

Я новичок в написании сценариев VBS. Я получаю сообщение об ошибке выше в строке 54, символ 5 в сценарии ниже. Эта ошибка говорит: «Объект не поддерживает это свойство или метод:« MimeMapArray »».

И строка, на которую он ссылается: MimeMapArray(i) = CreateObject("MimeMap")

Можете ли вы сказать мне, что я делаю неправильно? Вот сценарий целиком. Обратите внимание: я пытаюсь запустить это в ОС XP, дважды щелкнув этот файл VBS.

' This script adds the necessary Windows Presentation Foundation MIME types 
' to an IIS Server.
' To use this script, just double-click or execute it from a command line.
' Running this script multiple times results in multiple entries in the IIS MimeMap.
' Set the MIME types to be added
Dim MimeMapObj
Dim MimeMapArray
Dim WshShell
Dim oExec
Const ADS_PROPERTY_UPDATE = 2

Dim MimeTypesToAddArray
MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _
    "application/xaml+xml", ".application", "application/x-ms-application", _
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _
    ".xps", "application/vnd.ms-xpsdocument")

' Get the mimemap object 
Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap")

' Call AddMimeType for every pair of extension/MIME type
For counter = 0 to UBound(MimeTypesToAddArray) Step 2
    AddMimeType MimeTypesToAddArray(counter), MimeTypesToAddArray(counter+1)
Next

' Create a Shell object
Set WshShell = CreateObject("WScript.Shell")

' Stop and Start the IIS Service
Set oExec = WshShell.Exec("net stop w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = WshShell.Exec("net start w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = Nothing

' Report status to user
WScript.Echo "Windows Presentation Foundation MIME types have been registered."

' AddMimeType Sub
Sub AddMimeType(ByVal Ext, ByVal MType)

    ' Get the mappings from the MimeMap property. 
    MimeMapArray = MimeMapObj.GetEx("MimeMap")

    ' Add a new mapping. 
    i = UBound(MimeMapArray) + 1
    ReDim Preserve MimeMapArray(i)
    MimeMapArray(i) = CreateObject("MimeMap")
    MimeMapArray(i).Extension = Ext
    MimeMapArray(i).MimeType = MType
    MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", MimeMapArray
    MimeMapObj.SetInfo()

End Sub

runtime-error vbscript
person salvationishere    schedule 09.03.2010    source источник

Ответы (1)


arrow_upward
2
arrow_downward

Первое, что я могу предложить, это использовать cscript для выполнения. Вы можете получить больше информации, которая не исчезнет, ​​как с окном сообщения.

  1. Откройте командную строку (запустите, запустите, введите CMD).
  2. Перейдите в место, где находится ваш скрипт, и введите следующее:

cscript имя_скрипта.vbs

...где scriptname.vbs — это имя вашего скрипта.

Во-вторых, вам, похоже, не хватает «набора» перед вашей строкой createobject. Посмотрите здесь для справки.

Эта строка должна выглядеть так:

set MimeMapArray(i) = CreateObject("MimeMap")
person Michael Beck    schedule 15.03.2010