Менеджер накопления памяти

Поскольку все НЕ ПРОШЛИ предоставить подробное решение. Вот решение, которое действительно работает.

1: Откройте libhoard.cpp 2: Добавьте в код следующие строки.

extern "C"{

__declspec(dllexport) void* scalable_malloc (size_t size)
{
    return malloc(size);
}

__declspec(dllexport) void* scalable_realloc (void* ptr, size_t size)
{
    return realloc(ptr, size);
}

__declspec(dllexport) void scalable_free (void* ptr)
{
    free(ptr);
}

}

3: Скомпилируйте с nmake windows

4: Используйте это

unit hoard_mm;

interface

implementation

type
  size_t = Cardinal;

const
  hoardDLL = 'libhoard.dll';

function scalable_malloc(Size: size_t): Pointer; cdecl; external hoardDLL;
function scalable_realloc(P: Pointer; Size: size_t): Pointer; cdecl; external hoardDLL;
procedure scalable_free(P: Pointer); cdecl; external hoardDLL;

function GetMem(Size: NativeInt): Pointer; inline;
begin
  Result := scalable_malloc(size);
end;

function FreeMem(P: Pointer): Integer; inline;
begin
  scalable_free(P);
  Result := 0;
end;

function ReallocMem(P: Pointer; Size: NativeInt): Pointer; inline;
begin
  Result := scalable_realloc(P, Size);
end;

function AllocMem(Size: NativeInt): Pointer; inline;
begin
  Result := GetMem(Size);
  if Assigned(Result) then
  FillChar(Result^, Size, 0);
end;

function RegisterUnregisterExpectedMemoryLeak(P: Pointer): Boolean; inline;
begin
  Result := False;
end;

const
  MemoryManager: TMemoryManagerEx = (
    GetMem: GetMem;
    FreeMem: FreeMem;
    ReallocMem: ReallocMem;
    AllocMem: AllocMem;
    RegisterExpectedMemoryLeak: RegisterUnregisterExpectedMemoryLeak;
    UnregisterExpectedMemoryLeak: RegisterUnregisterExpectedMemoryLeak
  );

initialization
  SetMemoryManager(MemoryManager);

end.