Как получить пакетное время изменения и время создания файла, не зависящие от локали?

Я выложу несколько вариантов

1) Первый - с wmic (недоступен для домашней версии XP) (LastModified можно изменить с помощью CreationDate или LastAccessed)

@echo off

set file_loc=.\temp_file
for %%# in ("%file_loc%") do set file_loc=%%~dpfnx#
set file_loc=%file_loc:\=\\%


for /f "delims=." %%t in ('"WMIC DATAFILE WHERE name="%file_loc%" get LastModified /format:value"') do (
    for /f %%$ in ("%%t") do if "%%$" neq "" set %%$
)

echo %LastModified%
echo year : %LastModified:~0,4%
echo month : %LastModified:~4,2%
echo day : %LastModified:~6,2%

2). Гибрид Jscript / .bat (DateLastModified можно изменить на DateCreated или DateLastAccessed. Формат времени можно изменить на все, что захотите):

@if (@X)==(@Y) @end /****** jscript comment ******
@echo off

set file_loc=.\temp_file
for %%# in ("%file_loc%") do set file_loc=%%~dpfnx#
::set file_loc=%file_loc:\=\\%
cscript //E:JScript //nologo "%~f0" "%file_loc%"
exit /b 0

****** end of jscript comment ******/

var file_loc = WScript.Arguments.Item(0);
var fso = new ActiveXObject("Scripting.FileSystemObject");
var the_file=fso.GetFile(file_loc);
var the_date= new Date(the_file.DateLastModified);
WScript.Echo(the_date.getFullYear());
WScript.Echo(the_date.getMonth());
WScript.Echo(the_date.getUTCDate());

3) самокомпилированный гибрид jscript.net/bat (GetLastWriteTime можно изменить на GetLastAccessTime или GetCreationTime. Можно изменить формат времени):

@if (@X)==(@Y) @end /****** silent line that start jscript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"
:: searching the latest installed .net framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       end of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation



set file_loc=.\temp_file
for %%# in ("%file_loc%") do set file_loc=%%~dpfnx#


"%~n0.exe" "%file_loc%"


exit /b 0


****** end of jscript comment ******/
import System;
import System.IO;

var arguments:String[] = Environment.GetCommandLineArgs();

var the_file=arguments[1];
var last_modified=File.GetLastWriteTime(the_file);
 Console.WriteLine(last_modified.ToString("yyyy-MM-dd"));

4). robocopy - с помощью этого вы можете получить только дату последнего изменения (с помощью других методов вы можете получить все атрибуты времени). Поскольку временные метки в robocopy всегда YYYY/MM/DD HH:mm:SS, это можно использовать ...

@ECHO OFF

set file_loc=.\temp_file
for %%# in ("%file_loc%") do set file_dir=%%~dp#
for %%# in ("%file_loc%") do set file_name=%%~nx#
pushd %file_dir%

for /f "tokens=1,2" %%a in ('robocopy  "." "%temp%" /l /fat /ts /LEV:1 /NP /NC /NS /NJS /NJH^|findstr /i /e /c:"%file_name%"') do (
    echo %%a %%b
)
popd

РЕДАКТИРОВАТЬ Вот готовые к использованию параметризованные скрипты, использующие все перечисленные методы:

1. fileModifiedTime.bat - получает время последнего изменения файла с формат, не зависящий от настроек. На основе robocopy
2. fileTimes.bat - получает метки времени файла с WMIC
3. dirTimes.bat - получает метки времени каталога с WMIC
4. fileTimesJS.bat - отметки времени файла с < strong> jscript
5. dirTimesJS.bat - отметки времени каталога с < strong> jscript
6. fileTimesNET.bat - отметки времени файла с .NET
7. dirTimesNET.bat - метки времени dir с .NET