Проверка элементов массива as3

Я посмотрел на ваш .fla. Вот два способа сделать то, что вы хотите:

На вашей основной временной шкале: (замените текущий код кадра 1 основной временной шкалы следующим)

stop(); 

//loop through every child of the `cont` container, and add the same click listener
var i:int = cont.numChildren
while(i--){
    var tile:MovieClip = cont.getChildAt(i) as MovieClip;
    if(tile){
       tile.addEventListener(MouseEvent.CLICK, tileClick, false,0,true);
    }
}

function tileClick(e:MouseEvent):void {
    //this gets a reference to one that was clicked
    var tile:MovieClip = e.currentTarget as MovieClip;

    tile.gotoAndStop(2);

    //loop through the tile array to see if any are still visible
    var i:int = cont.numChildren
    while(i--){
        tile = cont.getChildAt(i) as MovieClip;
        if(tile && tile.currentFrame == 1) return;
    }

    //if we got this far, all the tiles are hidden, lets go to frame 5.
    gotoAndStop(5);
}

Если приведенное выше пугает и вы предпочитаете оставить все как было раньше, то это все, что вам нужно сделать: (опять же, этот код заменит ваш текущий основной код кадра 1 временной шкалы)

stop();

cont.tile1.addEventListener(MouseEvent.CLICK, tileClick);
cont.tile2.addEventListener(MouseEvent.CLICK, tileClick);
cont.tile3.addEventListener(MouseEvent.CLICK, tileClick);
cont.tile4.addEventListener(MouseEvent.CLICK, tileClick);

function tileClick(e:MouseEvent):void {
    MovieClip(e.currentTarget).gotoAndStop(2);
    if(cont.tile1.currentFrame == 1) return;
    if(cont.tile2.currentFrame == 1) return;
    if(cont.tile3.currentFrame == 1) return;
    if(cont.tile4.currentFrame == 1) return;

    //if we got this far, all the tiles are hidden, lets go to frame 5.
    gotoAndStop(5);
}