Неопределенные подпрограммы и основная ошибка в Perl

Похоже, вы никуда не денетесь с этим.

Я думаю, что ваш выбор использовать модуль и подпрограммы немного странный, учитывая, что вы вызываете каждую подпрограмму только один раз и действительно соответствует очень небольшому количеству кода.

И ваша программа, и ваш модуль должны начинаться с use strict и use warnings, и вы не можете использовать подобные прототипы в подпрограммах Perl. Включая ряд других ошибок, это намного ближе к тому коду, который вам нужен.

package Fasta;

use strict;
use warnings;
use 5.010;
use autodie;

use base 'Exporter';

our @EXPORT = qw/ read_fasta read_seq print_seq_40 /;

sub read_fasta {
  my ($filename) = @_;

  open my $fh_in, '<', $filename;
  chomp(my @lines = <$fh_in>);

  @lines;
}

sub read_seq {
  my ($lines_ref) = $_[0];

  grep { not /^>/ } @$lines_ref;
}

sub print_seq_40 {
  my ($lines_ref) = @_;

  print "$_\n" for unpack '(A40)*', join '', @$lines_ref;
}

1;

q2.pl

use strict;
use warnings;

use Fasta qw/ read_fasta read_seq print_seq_40 /;

print "What is your filename: ";
my $filename = <STDIN>;
chomp $filename;

my @lines = read_fasta($filename);
my @seq = read_seq(\@lines);
print_seq_40(\@seq);

Вам нужно либо:

• добавить в свой модуль:

  use Exporter;
  our @EXPORT = qw ( read_fasta
                     read_seq ); #etc.
  

• вызовите код в удаленном модуле явно:

  fasta::read_fasta();
  

• явно импортировать модуль sub:

  use fasta qw ( read_fasta );
  

Также: Общее соглашение о модулях заключается в том, чтобы заглавная буква имени модуля использовалась в верхнем регистре.

В Perl, если вы use fasta;, это автоматически не экспортирует все его методы в пространство имен вашей программы. Вместо этого вызовите fasta::read_fasta.

Или: используйте Exporter для автоматического экспорта методов или включите что-то вроде use Fasta qw/read_fasta/.

Например:

package Fasta;
require Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw/read_fasta read_seq read_seq40/;

Использовать:

use Fasta qw/read_fasta read_seq read_seq40/;

Вы также можете заставить Fasta экспортировать все методы автоматически или определить ключевые слова для групповых методов, хотя последнее вызывало у меня некоторые проблемы в прошлом, и я бы рекомендовал его, только если вы уверены, что это стоит возможных проблем.

Если вы хотите сделать доступными все методы:

package Fasta;
use Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw/read_fasta read_seq read_seq40/;

Обратите внимание, что @EXPORT не является @EXPORT_OK. Последний позволяет импортировать их позже (как это сделал я), первый автоматически экспортирует все. Документация, на которую я ссылался, проясняет это.

Я просто заметил кое-что еще. Вы сглаживаете @_ в $filename в read_fasta. Я не уверен, что это работает. Попробуй это:

sub read_fasta {
   my $filename = $_[0]; # or ($filename) = @_; @_ is an array. $filename not.
}

Чтобы объяснить проблему: $filename = @_; означает: сохранить @_ (МАССИВ) в $filename (СКАЛАР). Perl делает это следующим образом: длина ARRAY сохраняется в $filename. Это не то, что вы хотите. Вам нужен первый элемент массива. Это будет $_[0].

Добавлен @ISA, который, вероятно, необходим, ИЛИ используйте комментарий от Borodir.