Как я могу несколько раз сопоставить конец строки в регулярном выражении без интерполяции?

Вопрос академический - в любом случае нет необходимости в якорях $ в вашем регулярном выражении. Вы должны использовать \n для соответствия новым строкам, потому что $ соответствует только промежутку между переводом строки и символом перед ним.

РЕДАКТИРОВАТЬ: я пытаюсь сказать, что вам никогда не понадобится использовать $ таким образом. Любое совпадение, которое простирается от одной строки к другой, должно каким-то образом использовать разделитель строк. Рассмотрим ваш пример:

/^\[INFO\]$(.*?)$\[INFO\]/ms

Если бы это скомпилировалось, (.*?) начал бы с использования первого перевода строки и продолжал бы работать, пока не совпадет с \nxyz, где второй $ завершится успешно. Но следующий символ — это перевод строки, и регулярное выражение ищет [, так что это не работает. После возврата (.*?) неохотно потреблял бы еще один символ — второй перевод строки — но тогда $ терпел неудачу.

Каждый раз, когда вы пытаетесь сопоставить EOL с $, а затем еще с чем-то, первым «материалом», который вам нужно будет сопоставить, будет перевод строки, так почему бы вместо этого не сопоставить его? Вот почему компилятор регулярных выражений Perl пытается интерпретировать $\ как имя переменной в вашем регулярном выражении: нет смысла иметь якорь в конце строки, за которым следует символ, который не является разделителем строк.

На основе ответа в perlfaq6 — Как я могу вытащить линии между двумя шаблонами, которые сами находятся на разных строках? , вот как будет выглядеть однострочник:

perl -0777 -ne 'print $1,"\n" while /\[INFO\]\s*(.*?)\s*\[INFO\]/sg' file.txt

Переключатель -0777 глотает весь файл сразу.

Однако, если вам нужна подпрограмма, которая дает вам возможность выбирать, какой тег вы хотите извлечь, File::Slurp упрощает задачу:

use strict;
use warnings;
use File::Slurp qw/slurp/;

sub extract {

    my ( $tag, $fileName ) = @_;
    my $text = slurp $fileName;

    my ($info) = $text =~ /$tag\s*(.*?)\s*$tag/sg;
    return $info;
}

# Usage:
extract ( qr/\[INFO\]/, 'file.txt' );

Когда регулярные выражения становятся слишком сложными, они, вероятно, являются неправильным инструментом. Я мог бы рассмотреть возможность использования здесь оператора флип-флоп. Оно ложно до тех пор, пока его левая часть не станет истинной, а затем остается истинным, пока его правая часть не станет истинной. Таким образом, вы можете выбрать, где начать и закончить извлечение, просто просматривая отдельные строки:

my $string = <<'HERE';
[INFO]
xyz
[INFO]
HERE

open my $string_fh, '<', \$string;

while( <$string_fh> )
    {
    next if /\[INFO]/ .. /\[INFO]/;
    chomp;

    print "Extracted <$_>\n";
    }

Если вы используете Perl 5.10, вы можете использовать обобщенную строку, оканчивающуюся на \R в регулярном выражении:

use 5.010;

my $string = <<'HERE';
[INFO]
xyz
[INFO]
HERE

my( $extracted ) = $string =~ /(?:\A|\R)\[INFO]\R(.*?)\R\[INFO]\R/;

print "Extracted <$extracted>\n";

Не зацикливайтесь на якоре в конце строки.

Возможно, модификатор /x может помочь:

m/ ^\[INFO\] $ # Match INFO line
   \n
   ^ (.*?) $ # Collect desired line
   \n 
   ^ \[INFO\] # Match another INFO line
/xms

Я не проверял это, поэтому вам, вероятно, придется отлаживать его. Но я думаю, что это предотвратит интерполяцию символов $ как переменных.

Хотя я принял ответ Алана Мура (ответ Райана Томпсона также сослужил бы злую шутку, я мог бы принять только один), я хотел сделать совершенно ясное решение, поскольку оно было как бы скрыто в комментариях и обсуждении. Следующий сценарий Perl демонстрирует, что Perl использует $ для интерполяции переменных, если какой-либо символ предшествует знаку доллара, и что отключение интерполяции позволит рассматривать $ как EOL.

use strict;
use warnings;

my $x = "[INFO]\nxyz\n[INFO]";
if( $x =~ /^\[INFO\]$\n(.*?)$\n\[INFO\]/m ) {
    print "'$1' FOUND\n";
} else {
    print "NO MATCH FOUND\n";
}

if( $x =~ m'^\[INFO\]$\n(.*?)$\n\[INFO\]'m ) {
    print "'$1' FOUND\n";
} else {
    print "NO MATCH FOUND\n";
}

if( $x =~ m/ ^\[INFO\] $ # Match INFO line
\n
^ (.*?) $ # Collect desired line
\n 
^ \[INFO\] # Match another INFO line
/xms ) {
    print "'$1' FOUND\n";
} else {
    print "NO MATCH FOUND\n";
}

Скрипт выдает следующий вывод:

Use of uninitialized value $\ in regexp compilation at t.pl line 5.
Use of uninitialized value $\ in regexp compilation at t.pl line 5.
NO MATCH FOUND
'xyz' FOUND
'xyz' FOUND