Скопируйте все из исходного каталога в новый каталог Delphi EX7

Вот пример (сделанный в XE7), который будет делать то, что вы хотите. Очевидно, вам нужно будет изменить его в соответствии с вашими потребностями; он имеет жестко закодированную информацию о пути и маске файла (*.png) и использует константу, чтобы решить, является ли файл большим или маленьким.

Он основан на этом образце дерева каталогов:

D:\TempFiles
  |--\Test
  |-----\A
  |-----\B
  |--------\SubB   
  |-----\NewFiles
  |-------\Large
  L-------\Small

Он находит все файлы .png в папке D:\TempFiles\Test и ее подпапках и копирует файлы размером более 10 КБ в D:\ TempFiles\NewFiles\Large и меньше 10 КБ в D:\TempFiles\NewFiles\Small.

Вам нужно будет добавить IOUtils и Types в предложение реализации uses.

procedure TForm1.Button1Click(Sender: TObject);
var
  aLargeFiles: TStringDynArray;
  aSmallFiles: TStringDynArray;
const
  LargeSize = 10 * 1024;
  SourcePath = 'D:\TempFiles\Test\';
begin
  aLargeFiles := TDirectory.GetFiles(SourcePath, '*.png',
                   TSearchOption.soAllDirectories,
                   function (const Path: string; const SR: TSearchRec): Boolean
                   begin
                     Result := (SR.Size >= LargeSize);
                   end);
  aSmallFiles := TDirectory.GetFiles(SourcePath, '*.png',
                   TSearchOption.soAllDirectories,
                   function(const Path: string; const SR: TSearchRec):Boolean
                   begin
                     Result := (SR.Size < LargeSize);
                   end);
  CopyFilesToPath(aLargeFiles, 'D:\TempFiles\NewFiles\Large\');
  CopyFilesToPath(aSmallFiles, 'D:\TempFiles\NewFiles\Small\');
end;

procedure TForm1.CopyFilesToPath(aFiles: array of string; DestPath: string);
var
  InFile, OutFile: string;
begin
  for InFile in aFiles do
  begin
    OutFile := TPath.Combine( DestPath, TPath.GetFileName( InFile ) );
    TFile.Copy( InFile, OutFile, True);
  end;
end;