Файл .class не содержит имен переменных, хотя настройка для их создания активирована

На самом деле в самом файле класса нет ничего, что хранило бы имя параметра метода. Если вы посмотрите раздел 4.3. 3 вы увидите следующие определения для MethodDescriptor:

Дескриптор метода представляет параметры, которые принимает метод, и значение, которое он возвращает:

MethodDescriptor:
    ( ParameterDescriptor* ) ReturnDescriptor
A parameter descriptor represents a parameter passed to a method:

ParameterDescriptor:
    FieldType

Дескриптор возврата представляет собой тип значения, возвращаемого методом. Это ряд символов, сгенерированных грамматикой:

ReturnDescriptor:
    FieldType
    VoidDescriptor

VoidDescriptor:
    V

Символ V указывает на то, что метод не возвращает значения (тип возвращаемого значения — void).

Вы можете увидеть это, если распечатаете байт-код для Person.class и PersonImpl.class, используя javap -c:

Compiled from "Person.java"
public interface Person {
  public abstract void setName(java.lang.String);

  public abstract void setAge(int);
}

Compiled from "PersonImpl.java"
public class PersonImpl implements Person {
  public PersonImpl();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public void setName(java.lang.String);
    Code:
       0: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
       3: new           #3                  // class java/lang/StringBuilder
       6: dup
       7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      10: ldc           #5                  // String This is my name:
      12: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      15: aload_1
      16: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      22: invokevirtual #8                  // Method java/io/PrintStream.println:(Ljava/lang/String;)V
      25: return

  public void setAge(int);
    Code:
       0: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
       3: new           #3                  // class java/lang/StringBuilder
       6: dup
       7: invokespecial #4                  // Method java/lang/StringBuilder."<init>":()V
      10: ldc           #9                  // String This is my age:
      12: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      15: iload_1
      16: invokevirtual #10                 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
      19: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      22: invokevirtual #8                  // Method java/io/PrintStream.println:(Ljava/lang/String;)V
      25: return
}

Вы можете видеть, что подпись метода ничего не говорит об имени параметра; только его тип.

Я подозреваю, что JD-Gui, вероятно, использует какую-то эвристику, основанную на соглашениях JavaBeans, для получения имени параметра. Поскольку имя метода — setName, предполагается, что имя параметра — name. Попробуйте изменить имя параметра на другое, отличное от name, и посмотрите, что выведет JD-Gui.

Отладочная информация, такая как локальные переменные, появится, если вы компилируете с использованием -g или -g:vars; он не отображается по умолчанию. Они отображаются в атрибуте LocalVariableTable. Из раздела 4.7.13:

Обратите внимание на необязательную часть; вот почему вы не видите его по умолчанию. Теперь, если вы посмотрите на раздел 4.7 .3 для атрибута Code:

Атрибут Code является атрибутом переменной длины в таблице атрибутов структуры method_info (§4.6). Атрибут Code содержит инструкции виртуальной машины Java и вспомогательную информацию для метода, включая метод инициализации экземпляра или метод инициализации класса или интерфейса (§2.9).

Если метод является нативным или абстрактным, его структура method_info не должна иметь атрибута Code в таблице атрибутов. В противном случае его структура method_info должна иметь ровно один атрибут Code в своей таблице атрибутов.

Поскольку определения методов интерфейса фактически абстрактны (если только вы не используете методы по умолчанию), вы не увидите для них запись LocalVariableTable. Я использовал последнюю версию JD-Gui для PersonImpl.class, которая была не скомпилирована с -g, и обнаружила, что она не отображает name и age. Вместо этого он отображал paramString и paramInt точно так же, как вы видели для Person.class. Однако, если вы скомпилируете его с флагом -g, вы увидите name и age.

Это связано с тем, что метод abstract находится в интерфейсе. Информация об именах параметров метода содержится в атрибут LocalVariableTable в байт-коде, который присутствует в атрибуте Code:

Атрибут LocalVariableTable является необязательным атрибутом переменной длины в таблице атрибутов атрибута Code (§4.7.3).

Атрибут Code определяется следующим образом:

Атрибут Code является атрибутом переменной длины в таблице атрибутов структуры method_info (§4.6). Атрибут Code содержит инструкции виртуальной машины Java и вспомогательную информацию для одного метода, метода инициализации экземпляра (§2.9) или метода инициализации класса или интерфейса (§2.9). Каждая реализация виртуальной машины Java должна распознавать атрибуты кода. Если используется метод native или abstract, его структура method_info не должна иметь атрибута Code. В противном случае его структура method_info должна иметь ровно один атрибут Code.

Как объясняется в других ответах, наличие LocalVariableTable зависит от наличия атрибута Code и, следовательно, недоступно для методов abstract. Обратите внимание, что в Java 8 появился атрибут для сохранения имен параметров, который работает независимо от отладочной информации. Создание этого атрибута должно быть выбрано с помощью флага времени компиляции:

Учитывая ваш interface:

public interface Person {
    void setName(String name);
    void setAge(int age);
}

> javac Person.java

> javap -v Person
Classfile /C:/Users/pietsch/AppData/Local/Temp/Person.class
  Last modified 11.06.2015; size 159 bytes
  MD5 checksum 2fc084aa2f41b0b98e1417be7faeff8b
  Compiled from "Person.java"
public interface Person
  minor version: 0
  major version: 52
  flags: ACC_PUBLIC, ACC_INTERFACE, ACC_ABSTRACT
Constant pool:
   #1 = Class              #9             // Person
   #2 = Class              #10            // java/lang/Object
   #3 = Utf8               setName
   #4 = Utf8               (Ljava/lang/String;)V
   #5 = Utf8               setAge
   #6 = Utf8               (I)V
   #7 = Utf8               SourceFile
   #8 = Utf8               Person.java
   #9 = Utf8               Person
  #10 = Utf8               java/lang/Object
{
  public abstract void setName(java.lang.String);
    descriptor: (Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_ABSTRACT

  public abstract void setAge(int);
    descriptor: (I)V
    flags: ACC_PUBLIC, ACC_ABSTRACT
}
SourceFile: "Person.java"

> javac -parameters Person.java

> javap -v Person
Classfile /C:/Users/pietsch/AppData/Local/Temp/Person.class
  Last modified 11.06.2015; size 213 bytes
  MD5 checksum 63dfd86ff035e339baf7b9e9ae65020f
  Compiled from "Person.java"
public interface Person
  minor version: 0
  major version: 52
  flags: ACC_PUBLIC, ACC_INTERFACE, ACC_ABSTRACT
Constant pool:
   #1 = Class              #12            // Person
   #2 = Class              #13            // java/lang/Object
   #3 = Utf8               setName
   #4 = Utf8               (Ljava/lang/String;)V
   #5 = Utf8               MethodParameters
   #6 = Utf8               name
   #7 = Utf8               setAge
   #8 = Utf8               (I)V
   #9 = Utf8               age
  #10 = Utf8               SourceFile
  #11 = Utf8               Person.java
  #12 = Utf8               Person
  #13 = Utf8               java/lang/Object
{
  public abstract void setName(java.lang.String);
    descriptor: (Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_ABSTRACT
    MethodParameters:
      Name                           Flags
      name

  public abstract void setAge(int);
    descriptor: (I)V
    flags: ACC_PUBLIC, ACC_ABSTRACT
    MethodParameters:
      Name                           Flags
      age
}
SourceFile: "Person.java"

Я не знаю, может ли JD-Gui использовать эту информацию.