Как моделировать вложенные потоки с каналами?

Есть два основных подхода, которые я бы рекомендовал для этого. Самый простой — просто получить поток типов суммы, указывающий «другое значение» вместо «новой строки». Другой подход заключается в использовании комбинаторного подхода, такого как withLine или foldLines. Последний может быть построен поверх первого. Первоначально этот подход обсуждался в записи блога на foldLines.

Ниже приведен полный фрагмент кода, показывающий тип суммы и подход к комбинатору. Обратите внимание, что folded (вероятно, неудачное название для этого) — это функция общего назначения для преобразования во «вложенный поток» из типа суммы. Подход, используемый каналами (на основе FreeT IIRC), вероятно, может использоваться и каналом, но, как я упоминал в своем блоге, я думаю, что это более сложное решение, чем необходимо.

{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE NoImplicitPrelude #-}
import ClassyPrelude.Conduit
import Data.Text.Read (decimal, signed)

sumType :: Monad m => Conduit Text m (Maybe Int)
sumType =
    linesUnboundedC =$= mapMC toMaybeInt
  where
    toMaybeInt "" = return Nothing
    toMaybeInt t =
        case signed decimal t of
            Right (i, "") -> return $ Just i
            _ -> fail $ "Invalid int: " ++ show t

folded :: Monad m => Sink a m () -> Sink (Maybe a) m ()
folded perGroup =
    startGroup
  where
    startGroup = peekC >>= maybe (return ()) (const go)

    go = takeMaybes =$ (perGroup >> sinkNull) >> startGroup

    takeMaybes = await >>= maybe (return ()) (\x ->
        case x of
            Nothing -> return ()
            Just y -> yield y >> takeMaybes)

main :: IO ()
main = do
    let src = yield "1\n2\n3\n\n5\n6\n\n\n7"
    src $$ sumType =$ (sinkList >>= print)
    src $$ sumType =$ folded (sinkList >>= print)