Как заполнить ячейку строковой сетки, используя собственный цвет?

В процедуре OnDrawCell добавьте непосредственно перед FillRect

Rect.Left := Rect.Left-4;

Кажется, работает.

Альтернатива

Вышеупомянутое не полностью решает проблему фокусировки даже с вашим дополнением к процедуре рисования. Иногда белая линия видна только внутри границ ячейки.

Но ниже приведена альтернатива, которая решает обе ваши проблемы. Это требует немного больше кодирования, но не так много. С другой стороны, создание подкласса TStringGrid не требуется, ни настройка Rect

Основой является отключение рисования по умолчанию, поэтому установите свойство сетки DefaultDrawing := false;, а затем добавьте к событию OnDrawCell:

procedure TForm1.StringGridDrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  if gdFixed in State then
  begin
    StringGrid.Canvas.Brush.Color := clGradientInactiveCaption;
    StringGrid.Canvas.Font.Style := [];
    StringGrid.Canvas.Font.Color := clBlack;
  end
  else
  if gdSelected in State then
  begin
    StringGrid.Canvas.Brush.Color := $00940A4B;
    StringGrid.Canvas.Font.Style := [fsBold];
    StringGrid.Canvas.Font.Color := clHighlightText;
  end
  else
  begin
    StringGrid.Canvas.Brush.Color := $00FFFFFF;
    StringGrid.Canvas.Font.Style := [];
    StringGrid.Canvas.Font.Color := clWindowText;
  end;

  StringGrid.Canvas.FillRect(Rect);
  StringGrid.Canvas.TextOut(Rect.Left + 3, Rect.Top + 5, StringGrid.Cells[ACol,ARow]);
end;

Если отрисовка по умолчанию отключена, сетка рисует рамку сетки и линии сетки, но оставляет программисту все остальное рисование. Предостережение в том, что вы должны сами добавить причудливый тематический рисунок, если вам это нужно. С приведенным выше кодированием я получаю такой результат:

Я предполагаю, что вы (хотите) использовать настройку по умолчанию DefaultDrawing = True, иначе вашего вопроса не существует.

1. Чтобы избавиться от прямоугольника фокуса, вам нужно отрисовать его снова (поскольку это XOR-операция, прямоугольник фокуса исчезнет) или предотвратить его отрисовку.

   Рисование снова выполняется с использованием события OnDrawCell:

   procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
     Rect: TRect; State: TGridDrawState);
   begin
     if gdFocused in State then
       DrawFocusRect(StringGrid1.Canvas.Handle, Rect);
   end;
   

   Предотвращение рисования вообще, например. делается путем отключения возможности установить фокус на StringGrid. Я предполагаю, что вы не используете его редактор, так что это не должно вызывать дополнительных проблем с удобством использования.

   type
     TStringGrid = class(Vcl.Grids.TStringGrid)
     public
       function CanFocus: Boolean; override;
     end;
   
   function TStringGrid.CanFocus: Boolean;
   begin
     Result := False;
   end;
   

   На самом деле это немного странное рабочее решение, потому что вы все еще можете входить в элемент управления, и он продолжает реагировать на события клавиатуры.

2. Я не могу воспроизвести вашу проблему с отсечением с помощью этого кода (здесь XE2):

   procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
     Rect: TRect; State: TGridDrawState);
   begin
     if gdSelected in State then
     begin
       StringGrid1.Canvas.Brush.Color := $00940A4B;
       StringGrid1.Canvas.FillRect(Rect);
       StringGrid1.Canvas.Font.Style := [fsBold];
       StringGrid1.Canvas.Font.Color := clHighlightText;
       StringGrid1.Canvas.TextOut(Rect.Left + 3, Rect.Top + 5,
         StringGrid1.Cells[ACol, ARow]);
     end;
   end;
   

   Rect будет правильным CellRect. Эффект отсечения возникает из-за чего-то еще в другом месте.

   Но если в исходном коде XE8 действительно есть ложное +4, например Том Брунберг упоминает, что легко преодолевается с помощью -4, тогда это, очевидно, является ошибкой и о ней следует сообщить.