Почему значение переменной цикла не сохраняется в динамически созданном AnonymousThread

Это классическое недоразумение. Мы понимаем, что анонимные методы захватывают, но что они захватывают? Значение или переменная?

Ответ последний. Они фиксируют переменную. Существует единственная переменная thrn, которую захватывает каждый из ваших шести анонимных методов. Поскольку существует одна переменная, в любой момент времени существует только одно значение.

Конечно, поскольку вы выполняете код в потоках, у вас возникает гонка данных по этой переменной. Отсюда моя оговорка "в любой момент времени". И именно поэтому у вас есть неповторимые, непредсказуемые результаты. И вы, вероятно, получите доступ к переменной цикла после завершения цикла, и тогда значение не будет определено.

Если вы хотите иметь разные значения для каждого анонимного метода, вы должны создать новую переменную для каждого анонимного метода. Мой ответ на другой вопрос показывает, что: Анонимные методы - захват переменных и захват значений.

Итак, чтобы проиллюстрировать в вашем контексте, нам нужно еще несколько строительных лесов.

function GetThreadProc(thrn: Integer): TProc;
begin
  Result := 
    procedure
    begin
      // thrn is passed by value, so a copy is made, i.e. a new variable
      ....
    end;
end;

....

procedure TForm1.Button1Click(Sender: TObject);
var 
  thrn: Integer;
begin
  for thrn := 0 to 5 do
    TThread.CreateAnonymousThread(
      GetThreadProc(thrn)).Start;
end;

Вы должны зафиксировать значение вашего идентификатора. Вот пример, как это сделать.

procedure TForm1.Button1Click(Sender: TObject);
  function GetAnonProc( ID: Word): TProc;
  begin
    Result :=
      procedure
      var
        i: longint;
        r: double;
        thrns:string;
      begin
        thrns:= inttostr(ID);// Capture value
        repeat
          for i := 0 to 100000000 do
          begin
            r := random(high(i));//this loop gives some dummy job
            r := sqr(r);         //to the thread to slow it down
          end;
          TThread.Synchronize(nil,
            procedure()
            begin
              memo1.Text:=memo1.Text+#13#10+
                'done'+thrns;//it returns strange IDs including '6'
            end);
        until false;
      end;

  end;
var
  thrn:word;
  p: TProc;
begin
  for thrn := 0 to 5 do
  begin
    p := GetAnonProc(thrn); // Capture thrn value
    TThread.CreateAnonymousThread(p).Start;
  end;
end;

Приведенный выше код фиксирует 6 разных ссылок на локальную переменную ID. Каждый с разным значением.

Код в вопросе фиксирует ссылку на одну переменную. Поскольку вы не можете контролировать время выполнения потоков, невозможно предсказать, какое значение они получат из ссылки на переменную. Наблюдаемое вами значение 6 связано с тем, что значение переменной цикла не определено после завершения цикла.

Чтобы лучше понять, как работают анонимные методы и как использовать привязку переменных, прочтите Механизм привязки переменных.