Maple, максимальное значение числовой функции

Я пытаюсь вычислить максимальное значение решения системы с двумя ODE, используя Maple. Сначала я решил саму систему:

> with(DEtools):with(plots):
> a1:=0.00875;a2:=0.075;b1:=7.5;b2:=2.5;d1:=0.0001;d2:=0.0001;g:=4*10^(-8);K1:=5000;K2:=2500;n:=2;m:=2;

> dsol:= dsolve({
diff( x(t), t ) = a1+b1*x(t)^n/(K1^n+x(t)^n)-g*x(t)*y(t)-d1*x(t), 
diff( y(t), t ) = a2+b2*x(t)^m/(K2^m+x(t)^m)-d2*y(t), 
x(0) = 1000, y(0) = 1000}, numeric, output = listprocedure);

> xt:= eval( x(t), dsol );
yt:= eval( y(t), dsol );


> X:=plot(xt(t),t=0..50000,color=blue,legend="x(t)"):
Y:=plot(yt(t),t=0..50000,color=green,legend="y(t)"):
> display([X,Y]);

Я получил решения системы на xt и yt, но они являются числовыми решениями. Поэтому функция Maple Maximize() не работает:

> maximize(xt);
> maximize(xt(t),t=0..20000);

Можно ли вычислить максимальное значение числовой функции с помощью Maple?


function numeric maple
person S. Proa    schedule 19.03.2016    source источник

Ответы (1)


arrow_upward
2
arrow_downward

Каждая из ваших кривых xt и yt имеет один локальный максимум в пределах вашего диапазона t=0..50000, поэтому вы можете использовать пакет Optimization для этого простым способом.

restart;
with(plots):
a1:=0.00875: a2:=0.075: b1:=7.5: b2:=2.5: d1:=0.0001:
d2:=0.0001: g:=4*10^(-8): K1:=5000: K2:=2500: n:=2: m:=2:
dsol:= dsolve({diff(x(t),t)=a1+b1*x(t)^n/(K1^n+x(t)^n)-g*x(t)*y(t)-d1*x(t),
               diff(y(t),t)=a2+b2*x(t)^m/(K2^m+x(t)^m)-d2*y(t),
               x(0)=1000, y(0)=1000}, numeric, output=listprocedure):
xt:= eval(x(t), dsol):
yt:= eval(y(t), dsol):
X:=plot(xt(t), t=0..50000, color=blue, legend="x(t)"):
Y:=plot(yt(t), t=0..50000, color=green, legend="y(t)"):
xmax:=Optimization:-Maximize(xt, 0..50000):
[xmax[2][1],xmax[1]];

               [9460.78688552799, 11193.0618953179]

ymax:=Optimization:-Maximize(yt, 0..50000):
[ymax[2][1],ymax[1]];

               [21471.8648785947, 19006.6009784691]

display( Y, pointplot([[ymax[2][1],ymax[1]]], symbolsize=20),
         X, pointplot([[xmax[2][1],xmax[1]]], symbolsize=20) );

введите здесь описание изображения

Для вашего простого примера это работает очень хорошо.

Если ваш xt или yt имеет много локальных максимумов, вы можете попробовать вызвать Maximize с его опцией method=branchandbound.

Кроме того, есть другие подходы, при которых вы можете дополнить свою систему DE новыми зависимыми переменными, такими как, скажем, xd(t)=diff(x(t),t) (вместе с соответствующими IC) и заставить dsolve/numeric самостоятельно заметить, когда это становится равным нулю (крайняя точка), используя средства events, или используйте fsolve на нем.

person acer    schedule 21.03.2016
comment
Идеальный! Очень хорошее объяснение и действительно полезный код!! Большое спасибо!! - person S. Proa; 22.03.2016