Простой разбор вопросов с использованием PEG.js

Я получил ответ в группе Google PEG.js, который помог мне встать на правильный путь. Я публикую ответы на все три задачи в надежде, что они могут послужить элементарным руководством для других новичков в PEG, таких как я. Обратите внимание, что рекурсия не требуется.

Пример 1:

Это просто, если вы понимаете основные идиомы PEG.

start
  = Text+

Text
  = Numbers
  / Characters

Numbers
  = numbers: [0-9]+ {return numbers.join("")}

Characters
  = text: [a-z]+ {return text.join("")}

Пример 2:

Проблема здесь заключается в специфическом выборе дизайна генератора синтаксического анализатора PEG.js для выражений Peek (&expr и !expr). Оба заглядывают во входной поток, не потребляя никаких символов, поэтому я ошибочно предположил, что они ничего не возвращают. Однако оба они возвращают пустую строку. Я надеюсь, что автор PEG.js изменит это поведение, потому что (насколько я могу судить) это просто ненужный хлам, загрязняющий поток вывода. Пожалуйста, поправьте меня, если я ошибаюсь в этом!

В любом случае, вот обходной путь:

start
  = Text+

Text
  = Numbers
  / Words

Numbers
  = numbers: [0-9]+ {return numbers.join("")}

Words
  = text: Letter+ {return text.join("")}

Letter
  = !Numbers text: . {return text}

Пример 3:

Проблема в том, что такое выражение, как ('"' .* '"'), никогда не может быть успешным. PEG всегда жадный, поэтому .* потребляет оставшуюся часть входного потока и никогда не увидит вторую кавычку. Вот решение (которое, кстати, требует того же обходного пути Peek, что и в примере 2).

start
  = Words+

Words
  = QuotedString
  / Text

QuotedString
  = '"' quote: NotQuote* '"' {return quote.join("")}

NotQuote
  = !'"' char: . {return char}

Text
  = text: NotQuote+ {return text.join("")}

Для текущих версий pegjs вы можете попробовать:

Пример первый

Ввод: "abcdef1234567ghijklmn8901opqrs"

Желаемый результат: ["abcdef", "1234567", "ghijklmn", "8901", "opqrs"]

{
  /**
   * Deeply flatten an array.
   * @param  {Array} arr - array to flatten
   * @return {Array} - flattened array
   */
  const flatten = (arr) =>  Array.isArray(arr) ? arr.reduce((flat, elt) => flat.concat(Array.isArray(elt) ? flatten(elt) : elt), []) : arr
}

start = result:string {
  console.log(JSON.stringify(result))
  return result
}

string = head:chars tail:( digits chars? )* {
  return flatten([head,tail])
}

chars = [a-z]+ {
  return text()
}

digits = $[0-9]+ {
  return text()
}

Пример 2

Должно быть легко сделать вывод из ответа выше.

Пример 3

Ввод: 'abcdefghijklmnop"qrstuvwxyz"abcdefg'

Желаемый результат: ["abcdefghijklmnop", "qrstuvwxyz", "abcdefg"]

{
  /**
   * Deeply flatten an array.
   * @param  {Array} arr - array to flatten
   * @return {Array} - flattened array
   */
  const flatten = (arr) =>  Array.isArray(arr) ? arr.reduce((flat, elt) => flat.concat(Array.isArray(elt) ? flatten(elt) : elt), []) : arr
}

start = result:string {
  console.log(JSON.stringify(result))
  return result
}

string = head:chars tail:quote_chars* {
  return flatten([head,tail])
}

quote_chars = DQUOTE chars:chars {
  return chars
}

chars = [a-z]+ {
  return text()
}

DQUOTE = '"'

Пример 1

start
  = alnums

alnums
  = alnums:(alphas / numbers) {
    return alnums;
  }

alphas
  = alphas:$(alpha+)

numbers
  = numbers:$(number+)

number
  = [0-9]

alpha
  = [a-zA-Z]

Пример 2

игнорировать

Пример 3

> 'abcdefghijklmnop"qrstuvwxyz"abcdefg'.split('"')
[ 'abcdefghijklmnop',
  'qrstuvwxyz',
  'abcdefg' ]