Решение 2. Период. Подробности смотрите в замечательных комментариях от @chrisian и @ dirk-trilsbeek.

Что касается вашего следующего вопроса о картировании полей. Более удобные для пользователя имена отлично подходят для людей, использующих BAPI вне SAP, но они затрудняют сопоставление с полями, которые мы знаем внутри SAP. К счастью, в этих случаях SAP большую часть времени использовала одни и те же элементы данных, так что это один из способов их сопоставления. В противном случае различные BAPI часто имеют функциональные модули преобразования для преобразования из полей BAPI в поля базы данных. Для материала BAPI, который вы упомянули, вы можете проверить подпрограммы ‹TABLE› _UEBERGEBEN (это переводится как ‹TABLE› _TRANSFER), где ‹TABLE› - это MARA, MARC и т. Д. Обратите внимание, что, например, процедура MARA_UEBERGEBEN вызывает FM MAP2I_BAPI_MARA_TO_MARA_UEB, и этот FM имеет перевод из структуры BAPI в MARA, например NET_WEIGHT соответствует NTGEW.

Используйте Решение 1, НО эти настраиваемые поля следует назначить группе заранее! Это нужно сделать в настройке по пути:

Общая логистика-> Основные записи материалов-> Выбор поля-> Назначьте поля группе выбора полей

Вам следует создать новую группу, если групп еще нет. Эта группа определяет, когда поля будут включены / отключены / активны / неактивны и т. Д. Код должен выглядеть так:

CALL FUNCTION 'MATERIAL_MAINTAIN_DARK'
 EXPORTING
  sperrmodus = ' '
  kz_prf = 'W'
  max_errors = ' '
  p_kz_no_warn = 'X'
  kz_verw = 'X'
  kz_aend = 'X'
  kz_dispo = 'X'
  kz_test = ' '
  flag_muss_pruefen = ' '
  call_mode = 'ACT'
 IMPORTING
  matnr_last = w_matnr_last
  number_errors_transaction = w_nb_errors
 TABLES
  amara_ueb = t_amara_ueb
  amarm_ueb = t_amarm_ueb
 EXCEPTIONS
  kstatus_empty = 1
  tkstatus_empty = 2
  t130m_error = 3
  internal_error = 4
  too_many_errors = 5
  update_error = 6
 OTHERS = 7.

 IF sy-subrc <> 0.
  MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO.
 ELSE.
  COMMIT WORK.
 ENDIF.

Наконец, это решение выбрано. Мы использовали BAPI_MATERIAL_SAVEDATA с расширением. Я прокомментировал код, чтобы помочь вам, если вы хотите его использовать :)

FORM update_mara
  USING
    us_result TYPE mara. "Input entry of mara with masterdata to update in the system

  DATA :  ls_mara           TYPE bapi_te_mara,
          ls_head           TYPE bapimathead,
          lt_extensionin    TYPE TABLE OF bapiparex,
          ls_extensionin    TYPE bapiparex,
          lt_extensioninx   TYPE TABLE OF bapiparexx,
          ls_extensioninx   TYPE bapiparexx,
          ls_return         TYPE bapiret2,
          lv_x              TYPE char41,
          lv_mara           TYPE string. "Container for all data of ls_mara

  " MASTERDATA PART
  MOVE-CORRESPONDING us_result TO ls_mara.
  ls_mara-material = ls_head-material = us_result-matnr.
  "At least the mendatory key field: 'material'

  " DATA PART
  " Use extension BAPI_TE_MARA
  ls_extensionin-structure = 'BAPI_TE_MARA'.
  lv_mara = ls_mara.
  " Fill data into the extension
  ls_extensionin+30(960) = lv_mara.
  APPEND ls_extensionin TO lt_extensionin.

  " FLAG PART
  CLEAR lv_x.
  DO 41 TIMES. "Don't forget to change 'lv_x TYPE char41' if needed
    CONCATENATE lv_x 'X' INTO lv_x.
    "Add an 'X' where you want to activate the update
    "Here, it's for all fields
  ENDDO. " End of the do loop for all fields of the mara

  " Use extension BAPI_TE_MARAX
  ls_extensioninx-structure  = 'BAPI_TE_MARAX'.
  ls_extensioninx-valuepart1(18)  = us_result-matnr.
  ls_extensioninx-valuepart1+19   = lv_x.
  " The first part (18) of the extensioninx is the matnr and the next ones some 'X' flags to activate the update or not.
  APPEND ls_extensioninx TO lt_extensioninx.

  " PROCESS PART
  CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
    EXPORTING
      headdata     = ls_head
    IMPORTING
      return       = ls_return
    TABLES
      extensionin  = lt_extensionin
      extensioninx = lt_extensioninx
  .

  IF ls_return-type = 'E'.
    CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
  ELSE.
    CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
      EXPORTING
        wait = 'X'.
  ENDIF.  " End if of check of BAPI result

ENDFORM.                    " UPDATE_MARA

Решение № 3 просто НЕ ДЕЙСТВИТЕЛЬНО в системах SAP.

Оба решения 1 и 2 хороши. Вы можете напрямую заполнить поля custo-field, как вы это делали в решении 3, после того, как вы изменили стандартные поля с помощью одного из FM.