Встроенная поддержка PowerBI - зацикливание, отключение и добавление данных из внешнего файла

Я пытаюсь выполнить нижеприведенное с помощью PowerQuery M

1) Откройте набор файлов (находится в папке на общем диске)

2) Получите данные в листе под названием «BC Ongoing Projects».

3) Переставьте данные (в основном отмените разворот набора столбцов (имя столбца меняется для каждого файла) 4) Добавьте их друг под другом

Я попытался использовать приведенный ниже код, но у меня возникла ошибка: «Имя ReOrganizedTable не распознано. Убедитесь, что оно написано правильно.»

let

//Get data from file in folder
Source = Folder.Files(Link_StaffDataLocation),
#"Get the files" = Table.SelectRows(Source, each [Extension] = ".csv" or [Extension] = ".txt" or Text.StartsWith([Extension], ".xls")),
#"Removed Columns" = Table.RemoveColumns(#"Get the files",{"Date accessed", "Date modified", "Date created", "Attributes", "Folder Path"}),
GetExcelContentIntoColumn = Table.AddColumn(#"Removed Columns", "Custom", each if Text.StartsWith([Extension], ".xls") then Excel.Workbook( [Content]) else null),
ExpandContent = Table.ExpandTableColumn(GetExcelContentIntoColumn, "Custom", {"Name", "Data", "Kind"}, {"Custom.Name", "Custom.Data", "Custom.Kind"}),
#"Filtered Rows" = Table.SelectRows(ExpandContent, each ([Custom.Name] = "BC Ongoing Projects") ),

//Create files name list
FileNameListStep1 = Table.Column(#"Filtered Rows","Name"),
FileNameListStep2 = List.Skip(FileNameListStep1,1),

//Filter on first filename
IterationFunction = (IterationList) =>
let
    CurrentFilenameList = List.Skip(IterationList,1),
    CurrentFilename = CurrentFilenameList{0},
    FilterOneDataSetAtATime = Table.SelectRows(#"Filtered Rows", each ([Name] = CurrentFilename)),
    // Make necessary adjustments to data
    #"Custom Data1" = #"Filtered Rows"{0}[Custom.Data],
    #"Filtered Rows1" = Table.SelectRows(#"Custom Data1", each ([Column1] <> null and [Column1] <> "BC Ongoing Projects" and [Column1] <> "Filters Used To Select These Practitioners:" and [Column1] <> "Pract" and [Column1] <> "Scheduled Hours" and [Column1] <> "Total:")),
    #"Removed Columns1" = Table.RemoveColumns(#"Filtered Rows1",{"Column5"}),
    #"Replaced Value_DK" = Table.ReplaceValue(#"Removed Columns1","DK","",Replacer.ReplaceText,{"Column4"}),
    #"Replaced Value_SE" = Table.ReplaceValue(#"Replaced Value_DK","SE","",Replacer.ReplaceText,{"Column4"}),
    #"Replaced Value" = Table.ReplaceValue(#"Replaced Value_SE",null,0,Replacer.ReplaceValue,{"Column6", "Column7", "Column8", "Column9", "Column10", "Column11", "Column12", "Column13", "Column14", "Column15", "Column16", "Column17"}),
    #"Changed Type" = Table.TransformColumnTypes(#"Replaced Value",{{"Column6", type text}, {"Column7", type text}, {"Column8", type text}, {"Column9", type text}, {"Column10", type text}, {"Column11", type text}, {"Column12", type text}, {"Column13", type text}, {"Column14", type text}, {"Column15", type text}, {"Column16", type text}, {"Column17", type text}}),
    #"Promoted Headers" = Table.PromoteHeaders(#"Changed Type"),
    //Create List of week dates    
    MondayInWeekStep1 = Table.ColumnNames(#"Promoted Headers"),
    MondayInWeekStep2 = List.Skip(MondayInWeekStep1,4),
    #"Unpivoted Columns" = Table.UnpivotOtherColumns(#"Promoted Headers", {"Name", "Client", "Type", "Key"}, "MondayInWeek", "Staff Hours"),
    ReOrganizedTable = Table.TransformColumnTypes(#"Unpivoted Columns",{{"MondayInWeek", type date}, {"Staff Hours", Int64.Type}})
in
    ReOrganizedTable,
    AppendTablesTogether = Table.Combine(ReOrganizedTable,IterationFunction(CurrentFilenameList))
in
AppendTablesTogether

Я очень ценю любую помощь, которую вы можете мне оказать

BR Jonas


loops powerbi powerquery m
person JSF    schedule 02.11.2016    source источник

Ответы (2)


arrow_upward
0
arrow_downward

ReOrganziedTable существует только в IterationFunction, который вы определили. Вероятно, вы захотите сделать следующее:

  1. Переместите шаг CurrentFilenameList в строку перед IterationFunction.
  2. Измените IterationFunction на CurrentFilename вместо IterationList. Другими словами, удалите шаг CurrentFilename в IterationFunction и измените (IterationList) => на (CurrentFilename) =>
  3. Используйте List.Transform для создания списка таблиц, а затем преобразуйте этот список в таблицу. Часть List.Transform должна делать что-то вроде List.Transform(FileNameListStep2, (filename) => IterationFunction(filename))
person Alejandro Lopez-Lago - MSFT    schedule 02.11.2016
comment
Большое тебе спасибо. Вы просто великолепны. - person JSF; 03.11.2016

arrow_upward
0
arrow_downward

Для всех, кто хочет увидеть готовый код:

let

//Get data from file in folder
Source = Folder.Files(Link_StaffDataLocation),
#"Get the files" = Table.SelectRows(Source, each [Extension] = ".csv" or [Extension] = ".txt" or Text.StartsWith([Extension], ".xls")),
#"Removed Columns" = Table.RemoveColumns(#"Get the files",{"Date accessed", "Date modified", "Date created", "Attributes", "Folder Path"}),
GetExcelContentIntoColumn = Table.AddColumn(#"Removed Columns", "Custom", each if Text.StartsWith([Extension], ".xls") then Excel.Workbook( [Content]) else null),
ExpandContent = Table.ExpandTableColumn(GetExcelContentIntoColumn, "Custom", {"Name", "Data", "Kind"}, {"Custom.Name", "Custom.Data", "Custom.Kind"}),
#"Filtered Rows" = Table.SelectRows(ExpandContent, each ([Custom.Name] = "BC Ongoing Projects") ),

//Create files name list
FileNameListStep1 = Table.Column(#"Filtered Rows","Name"),
CurrentFilename = FileNameListStep1{0},

//Filter on first filename
IterationFunction = (CurrentFilename) =>
let
    FilterOneDataSetAtATime = Table.SelectRows(#"Filtered Rows", each ([Name] = CurrentFilename)),
    // Make necessary adjustments to data
    #"Custom Data1" = #"Filtered Rows"{0}[Custom.Data],
    #"Filtered Rows1" = Table.SelectRows(#"Custom Data1", each ([Column1] <> null and [Column1] <> "BC Ongoing Projects" and [Column1] <> "Filters Used To Select These Practitioners:" and [Column1] <> "Pract" and [Column1] <> "Scheduled Hours" and [Column1] <> "Total:")),
    #"Removed Columns1" = Table.RemoveColumns(#"Filtered Rows1",{"Column5"}),
    #"Replaced Value_DK" = Table.ReplaceValue(#"Removed Columns1","DK","",Replacer.ReplaceText,{"Column4"}),
    #"Replaced Value_SE" = Table.ReplaceValue(#"Replaced Value_DK","SE","",Replacer.ReplaceText,{"Column4"}),
    #"Replaced Value" = Table.ReplaceValue(#"Replaced Value_SE",null,0,Replacer.ReplaceValue,{"Column6", "Column7", "Column8", "Column9", "Column10", "Column11", "Column12", "Column13", "Column14", "Column15", "Column16", "Column17"}),
    #"Changed Type" = Table.TransformColumnTypes(#"Replaced Value",{{"Column6", type text}, {"Column7", type text}, {"Column8", type text}, {"Column9", type text}, {"Column10", type text}, {"Column11", type text}, {"Column12", type text}, {"Column13", type text}, {"Column14", type text}, {"Column15", type text}, {"Column16", type text}, {"Column17", type text}}),
    #"Promoted Headers" = Table.PromoteHeaders(#"Changed Type"),
    //Create List of week dates    
    MondayInWeekStep1 = Table.ColumnNames(#"Promoted Headers"),
    MondayInWeekStep2 = List.Skip(MondayInWeekStep1,4),
    #"Unpivoted Columns" = Table.UnpivotOtherColumns(#"Promoted Headers", {"Name", "Client", "Type", "Key"}, "MondayInWeek", "Staff Hours"),
    ReOrganizedTable = Table.TransformColumnTypes(#"Unpivoted Columns",{{"MondayInWeek", type date}, {"Staff Hours", Int64.Type}}),
    AddFilenameColumn= Table.AddColumn(ReOrganizedTable, "FileName", each CurrentFilename)
in
    AddFilenameColumn,
    ListOfTables = List.Transform(FileNameListStep1, (filename) => IterationFunction(filename)),
    #"Converted to Table" = Table.FromList(ListOfTables, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    #"Expanded Column1" = Table.ExpandTableColumn(#"Converted to Table", "Column1", {"Name", "Client", "Type", "Key", "MondayInWeek", "Staff Hours", "FileName"}, {"Name", "Client", "Type", "EmployeeNr", "MondayInWeek", "Staff Hours", "FileName"})
in
  #"Expanded Column1"
person JSF    schedule 03.11.2016