Просмотр усеченных сообщений в Mathematica

Я не уверен, что вы можете восстановить длинное сообщение, которое уже было создано. Поскольку $MessageList и Message[] хранят только имена сообщений, а не переданные им аргументы.

Чтобы запретить автоматическое применение Short[] к сообщениям, вы можете Unset[$MessagePrePrint]. Значение по умолчанию — Automatic — что бы это ни влекло за собой.

Вместо того, чтобы постоянно печатать длинные сообщения, может быть лучше использовать что-то вроде

General::longmsg="A long message (`1`) was produced. The full message has been saved in `2`";
$MessagePrePrint=With[{bc=ByteCount[#]},If[bc>65536,
  With[{fn=FileNameJoin[{$HomeDirectory,StringJoin["MmaMsg",ToString/@DateList[]]}]},
    Put[#,fn];Message[General::longmsg,bc,Row[{fn}]];Short[Shallow[#],1]],
  #]]&;

Это распечатает сообщение как обычно, если только ByteCount не слишком велико (> 65536), и в этом случае будут распечатаны два сообщения: первое информирует вас о том, что было создано большое сообщение, и дает вам файл, в котором оно было сохранено. Второй — это усеченная версия полного сообщения.

Я сейчас не перед правильным компьютером, поэтому я не могу проверить это наверняка... Но я думаю, что вы можете полностью настроить поведение обработки сообщений с помощью чего-то вроде:

Block[{Message = f}, ...]

Например, вы можете использовать

f[args___] := Print[{args}];

Опять же, не перед Mathematica прямо сейчас. Пожалуйста, не стесняйтесь редактировать этот ответ в вики.

Недокументированная функция Internal`HandlerBlock (раскрыта Максимом Рытиным) здесь применимо:

Off[FindMaximum::"nrnum"]
Internal`HandlerBlock[{"Message", Print}, 
 Message[FindMaximum::"nrnum", arg1, arg2, arg3]]
(* => Hold[Message[FindMaximum::nrnum,arg1,arg2,arg3],False]*)

Другой тип обработчика — «MessageTextFilter». «Сообщение» вызывается для каждого сгенерированного сообщения и передает один аргумент формы Hold[..., ...] в функцию-обработчик, а второй элемент имеет значение False для скрытых сообщений. «MessageTextFilter» вызывается для сообщений, которые фактически распечатываются, и вызывает функцию с тремя аргументами.

Максим Рытин

Другая возможность состоит в том, чтобы изменить $MessagePrePrint таким образом, чтобы он печатал сообщения, содержащие встроенные ячейки с усеченными аргументами, которые могут быть расширены до полных аргументов при оценке. Это можно сделать с помощью Interpretation:

truncatingRules = {lst : {x_, y__} /; 
     MatrixQ[lst, NumberQ] && Length[lst] > 3 :>
    {x /. v : {a_, b__} /; Length[v] > 3 :>
       {a, 
        Interpretation[Style[Skeleton[Length[{b}]], Gray], 
         Sequence @@ {b}]},
     Interpretation[Style[Skeleton[Length[{y}]], Gray], 
      Sequence @@ {y}]},
   lst : {x_, y__} /; VectorQ[lst, NumberQ] && Length[lst] > 3 :>
    {x, Interpretation[Style[Skeleton[Length[{y}]], Gray], 
      Sequence @@ {y}]}};

InlineCellInsideMessage[expr_] := 
 Style[DisplayForm[
   Cell[BoxData[MakeBoxes[expr, StandardForm]], "Input"]], 
  FontWeight -> Bold, FontFamily -> "Courier", Background -> Yellow, 
  FontColor -> Red, FontSize -> 12, StripOnInput -> True, 
  AutoNumberFormatting -> True, ShowStringCharacters -> True]

$MessagePrePrint = 
 Function[expr, 
  If[TrueQ[ByteCount[Unevaluated[expr]] < $OutputSizeLimit/20.], 
   InlineCellInsideMessage[expr],
   InlineCellInsideMessage[expr /. truncatingRules]
   ]]

Конечно, приведенная выше версия $MessagePrePrint — это всего лишь набросок, но он иллюстрирует основную идею.

Цитирование этой ссылки:

«Когда вы выполняете символьные вычисления, довольно легко получить чрезвычайно сложные выражения. Часто вам даже не захочется видеть полный результат вычисления».

Вы можете управлять своим дисплеем с помощью Short.

Short[%, n] отобразит n строки вашего предыдущего результата, так что это может быть то, что вам нужно.

Подробнее здесь.