VBA: функция выдает ошибку времени выполнения «424»: объект требует ошибки при вызове

Под вашим ОП есть много хороших комментариев, а также ответ @BrandonBarney, но вот мои два цента:

Cent one: самое главное, что я вижу, это то, что вы никогда не объявляете blank_sheet, но пытаетесь использовать его при установке объекта диапазона. Вот откуда ваша ошибка. Он хочет сделать Range("1:1").Find("M_STORE"), но не знает, что такое bank_sheet.

Два цента: быстрый способ сообщить вам об этом — всегда используйте Option Explicit в начале кода. Это гарантирует, что любая переменная, которую вы используете, объявлена ​​явно. То есть:

Option Explicit

Function search_bank(Store As String, amount As Double, Amex As Boolean) As Boolean
    Dim m_store As Range
    Dim m_type As Range
    Dim Credit_Amt_Col As Range

    ''''' New code here: ''''''
    Dim bank_sheet as Worksheet
    Set bank_sheet = Worksheets("Bank Sheet") ' change to whatever the name is.
    '''''''''''''''''''''''''''
    Set m_store = bank_sheet.Range("1:1").Find("M_STORE")
    Set m_type = bank_sheet.Range("1:1").Find("M_TYPE")
    Set Credit_Amt_Col = bank_sheet.Range("1:1").Find("Credit Amt")
    ' etc. etc.

Option Explicit также поможет, если вы случайно сделаете опечатку. Поэтому, если вы когда-либо делали bank_sheeet.Range("A:A"), он выдаст ошибку и попросит вас объявить bank_sheeet. Или, конечно, вы поймете, что это опечатка, а затем просто исправите ее.

Бонусный цент: вы можете сэкономить несколько строк, объединив свои Dims:
Dim m_store as Range, m_type as Range, Credit_Amt_Col as Range могут быть в одной строке.

(Примечание. При выполнении Dim m_store, m_type, Credit_Amt_Col as Range не всем трем будет присвоен тип Range. Это сделает m_store и m_type типом Variant, поскольку он не объявлен. В этом случае только Credit_Amt_Col будет Range , Так что вам все равно придется явно указать тип для каждой переменной).

Я бы написал это как комментарий, если бы мог, но не могу. Поэтому я знаю, что это не решит проблему напрямую, но поможет в отладке. Смотри ниже:

Function search_bank(Store As String, amount As Double, Amex As Boolean) As Boolean
Dim m_store As Range
Dim m_type As Range
Dim Credit_Amt_Col As Range

' It is always best to check the inverse of an object before setting
' setting an object variable to the target object. In this case
' I check to make sure each range can be found, and if not, I
' debug.print which variable cannot be set.

Set m_store = bank_sheet.Range("1:1").Find("M_STORE")
Set m_type = bank_sheet.Range("1:1").Find("M_TYPE")
Set Credit_Amt_Col = bank_sheet.Range("1:1").Find("Credit Amt")

If m_store is Nothing then Debug.Print "m_store is nothing"
If m_type is Nothing then Debug.Print "m_type is nothing"
If Credit_Amt_Col is Nothing then Debug.Print "Credit_Amt_Col is nothing."

search_bank = False
Dim i As Long
For i = 1 To 9000
    If Not search_bank Then
        Dim store_cell As Range
        Dim type_cell As Range
        Dim credit_cell As Range

        ' Use the inverse method above on these three items as well.
        Set store_cell = Worksheets(2).Cells(i, m_store.Column)
        Set type_cell = Worksheets(2).Cells(i, m_type.Column)
        Set credit_cell = Worksheets(2).Cells(i, Credit_Amt_Col.Column)

        If InStr(UCase(store_cell.Value), UCase(Store)) > 0 And credit_cell.Value = amount Then
            If store_cell.Interior.ColorIndex <> 46 Then
                If Amex And InStr(UCase(type_cell.Value), UCase("amex deposit")) Then
                    store_cell.Interior.ColorIndex = 46
                    search_bank = True

                End If
                If Not Amex And InStr(UCase(type_cell.Value), UCase("Credit Card Deposit")) Then
                    store_cell.Interior.ColorIndex = 46
                    search_bank = True

                End If
            End If
        End If
    End If
Next i

End Function

Я разместил встроенный комментарий, но в основном я добавил обратную проверку для ваших первых трех объектов (вы могли бы сделать это и для второго набора объектов). Это лучшая практика, но в данном случае она также (надеюсь) поможет вам определить, где объект не может быть найден.