Есть ли способ резервного копирования и восстановления базы данных с помощью FireDAC?
Я использую Delphi 10.1 Berlin и подключаюсь к MSSQL Server. В идеале было бы создать резервную копию всех интересных атрибутов базы данных (записи, индексы и т. д.), но решение, которое просто выполняет резервное копирование и восстановление данных, было бы хорошо (я могу воссоздать все метаданные перед восстановлением).
Признаюсь, я немного озадачен вашим вопросом, потому что ответ кажется слишком простым, а именно использовать FireDAC TDFConnection для выполнения сценариев SqlServer TransactSql для резервного копирования и восстановления базы данных. Надеюсь, вы не считаете это читерством ;)
Пример кода проекта
type
TForm1 = class(TForm)
FDConnection1: TFDConnection;
btnBackUp: TButton;
btnRestore: TButton;
FDMetaInfoQuery1: TFDMetaInfoQuery;
FDPhysMSSQLDriverLink1: TFDPhysMSSQLDriverLink;
DBGrid1: TDBGrid; // connected to DataSource1
DataSource1: TDataSource; // connected to FDMetaInfoQuery1
Memo1: TMemo;
procedure btnBackUpClick(Sender: TObject);
procedure btnRestoreClick(Sender: TObject);
procedure FormCreate(Sender: TObject);
[...]
const
scBackUpPath = 'D:\MSSql2014\Backup\';
scBackupExtn = '.Bak';
procedure TForm1.Log(const Msg : String);
begin
Memo1.Lines.Add(Msg);
end;
function TForm1.DatabaseName: String;
begin
Result := FDMetaInfoQuery1.FieldByName('Catalog_Name').AsString;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
FDMetaInfoQuery1.MetaInfoKind := mkCatalogs; // gets list of databases
FDConnection1.Connected := True;
end;
procedure TForm1.BackupDB(const DBName: String);
var
FileName,
Sql : String;
begin
FileName := scBackUpPath + DBName + scBackUpExtn;
Sql := 'backup database %s to disk = ''%s''';
Sql := Format(Sql, [DBName, FileName]);
Log('Backing up ' + DBName + ' using SQL: ' + Sql);
try
Screen.Cursor := crHourGlass;
Update;
FDConnection1.ExecSQL(Sql);
Log('Done');
finally
Screen.Cursor := crDefault;
end;
end;
procedure TForm1.btnBackUpClick(Sender: TObject);
begin
BackUpDB(DatabaseName);
end;
procedure TForm1.btnRestoreClick(Sender: TObject);
begin
RestoreDB(DatabaseName);
end;
procedure TForm1.RestoreDB(const DBName: String);
var
FileName,
Sql : String;
begin
FileName := scBackUpPath + DBName + scBackUpExtn;
if FileExists(FileName) then begin
// Note: beware the 'with replace' in the following
Sql := 'restore database %s from disk = ''%s'' with replace';
Sql := Format(Sql, [DBName, FileName]);
Log('Restoring ' + DBName + ' using SQL: ' + Sql);
try
Screen.Cursor := crHourGlass;
Update;
FDConnection1.ExecSQL(Sql);
Log('Done');
finally
Screen.Cursor := crDefault;
end;
end
else
Log('Backup file ' + FileName + ' not found!');
end;
Очевидно, что это немного упрощает проверку ошибок, но я уверен, что вы поймете эту идею.
До того, как это было прекращено, я использовал автоматизацию Delphi для библиотеки SqlServer Sql-DMO, чтобы сделать это, потому что было легко реализовать обратные вызовы прогресса, такие как «% завершено».
Мне еще не удалось сделать ничего полезного с преемником Sql_DOM, SMO, от Delphi, и в эти дни я бы сделал это, используя TADOConnection, а не FireDAC, хотя бы потому, что при получении списка баз данных и коллекции ошибок ADO меньше багажа. обеспечивает простой способ получения любых обнаруженных ошибок.
