Как эффективно создать список простых чисел в Perl 6?

Я написал несколько привязок Perl 6 для primesieve:

https://github.com/CurtTilmes/perl6-primesieve

Математика::Примеси

Если вы запустите свою программу с --profile, вы увидите, что более 99% времени тратится на Int.is-prime. Поскольку это фактически просто оболочка вокруг nqp::isprime_I(), я попытался запустить аналогичный код без оболочки. Но это ничего заметно не меняет. Таким образом, основная работа выполняется в nqp::isprime_I().

Таким образом, единственный вариант, который у вас действительно есть, — это распараллелить поиск простых чисел. В (ближайшем) будущем hyper будет вашим другом здесь. Но в настоящее время это находится на этапе «начальной наивной реализации», а более надежная реализация обсуждается в: /gist.github.com/jnthn/6a80a9712fb38b32537f9f0e46fca6d7

До тех пор, если вы хотите работать быстрее, вам придется вручную разбить диапазон значений, которые вы хотите проверить на первичность, и запустить их в блоке start, а затем собрать результаты из полученного блока Promise.

На самом деле это не ответ на мой вопрос, но я проверил несколько способов получить список простых чисел.

Выводы:

1. .is-prime действительно слишком медленный для этого (хотя ветка @DanaJ, надеюсь, немного улучшит это).
2. Сито в коде Perl 6 не такое медленное, как я опасался, если вы немного оптимизируете вещи (т. е. делаете код менее привлекательным Perl6).
3. Нативный код (с помощью модуля Perl 5) по-прежнему намного быстрее.
4. Обман самый быстрый. ????

Изменить: добавлен модуль Primesieve Курта Тилмеса. Вау, это быстро! Это лучше, чем читерство (т.е. чтение простых чисел из файла)! Ну, это может быть потому, что Primesieve не поддерживает генератор/итератор (пока?), поэтому я просто возвращаю весь список сразу, в то время как все другие версии используют генератор/ленивый список.

Редактировать: добавлено «еще более оптимизированное» сито на основе комментария Тимбуса. У этого довольно приличная производительность, но код почти невозможно следовать...

Редактировать: добавлена ​​еще лучшая версия Perl6 с гибким размером сетки. Я начинаю с (предварительно инициализированного) сита для нечетных чисел 1..99 и при необходимости удваиваю размер сита. Вместе с некоторыми дополнительными оптимизациями (например, при расширении сита нам нужно проверять только простые числа до √(размер сита)) это, безусловно, самая быстрая чистая версия Perl 6 на данный момент. Дополнительные преимущества: вам не нужно заранее знать лимит; и это дает маленькие простые числа намного быстрее, если вам нужен высокий предел.

Изменить: Math::Primesieve теперь поддерживает итератор, поэтому включите его в сценарий.

#!/usr/bin/env perl6

use v6.c;

# The easy but slow way
sub primes-is-prime
{
    (^∞).grep: *.is-prime;
}

# Use a sieve (simple Perl 6 style)
sub primes-sieve(Int $max)
{
    my @sieve;
    lazy gather for 2..$max -> $p {
        next if @sieve[$p];
        take $p;
        for 2*$p, 3*$p ... $max -> $n {
            @sieve[$n] = True;
        }
    }
}

# Use a sieve (optimized)
sub primes-sieve2(Int $max)
{
    my int @sieve;
    lazy gather {
        take 2;
        loop (my int $p = 3; $p ≤ $max; $p += 2) {
            next if @sieve[$p];
            take $p;
            loop (my int $n = 3*$p; $n ≤ $max; $n += 2*$p) {
                @sieve[$n] = 1;
            }
        }
    }
}

# Use a sieve (even more optimized)
sub primes-sieve3(Int $max)
{
    my int @sieve;
    my $max2 = ($max-1) div 2;
    lazy gather {
        take 2;
        for 1 .. $max2 -> int $i {
            next if @sieve[$i];
            take 2*$i + 1;
            my $max3 = ($max2 - $i) div (2*$i + 1);
            for 1 .. $max3 -> int $j {
                @sieve[(2*$j + 1)*$i + $j] = 1;
            }
        }
    }
}

# Use a flexible sieve size (and further optimized)
sub primes-sieve4
{
    # Pre-initialize our sieve with the odd numbers from 1 to 99
    my $max = 100;
    my int @sieve = 1,0,0,0,1,0,0,1,0,0,1,0,1,1,0,0,1,1,0,1,0,0,1,0,1,
                    1,0,1,1,0,0,1,1,0,1,0,0,1,1,0,1,0,1,1,0,1,1,1,0,1;

    lazy gather {
        # Don't forget our single even prime number
        take 2;

        my int $min-i = 1;
        loop {
            # Take all primes in the new part of the sieve 
            my int $max-i = ($max-1) div 2;
            for $min-i .. $max-i -> int $i {
                take 2*$i + 1 unless @sieve[$i];
            }

            # Extend sieve by factor 2
            # We must check the primes from 3 to √(2*max) in the sieve
            # for max to 2*max
            for 1 .. ((2*$max).sqrt.floor-1) div 2 -> int $i {
                next if @sieve[$i];
                my int $p = 2*$i + 1;
                my int $min-j = max(($max-i - $i) div $p, $i);
                my int $max-j = (2*$max-i + 1 - $i) div $p;
                for $min-j .. $max-j -> int $j {
                    @sieve[$i + $p*$j] = 1;
                }
            }

            # Double the sieve size, and start the next iteration
            # in the second half of the sieve
            $max *= 2;
            $min-i = $max-i+1;
        }
    }
}

# Use a Perl 5 module
sub primes-perl5
{
    use Math::Prime::Util:from<Perl5> <prime_iterator>;

    my $it = prime_iterator;
    lazy gather {
        loop {
            take $it.();
        }
    }
}

# Use Primesieve module
sub primes-primesieve($max)
{
    # See:
    #  - http://primesieve.org/
    #  - https://github.com/CurtTilmes/perl6-primesieve
    use Math::Primesieve;

    # No iterator support (yet?), so just return the whole list
    return Math::Primesieve.new.primes($max);
}

# Use Primesieve module (iterator)
sub primes-primesieve-iterator
{
    # See:
    #  - http://primesieve.org/
    #  - https://github.com/CurtTilmes/perl6-primesieve
    use Math::Primesieve;
    my $iterator = Math::Primesieve::iterator.new;
    lazy gather {
        loop {
            take $iterator.next;
        }
    }
}

# Cheat
# Source: https://primes.utm.edu/lists/small/millions/ - first million
# (Unzip and remove the first few lines from the file.)
sub primes-cheat
{
    lazy $*PROGRAM.sibling('primes1.txt').words.map(+*);
}

sub timer(&code)
{
    my $start = now;
    &code();
    my $elapsed = now - $start;
    say "Elapsed: $elapsed.fmt('%.3f')s";
}

sub MAIN
{
    #my $nth = 1_000;
    #my $max = 8_000;

    #my $nth = 10_000;
    #my $max = 105_000;

    my $nth = 50_000;
    my $max = 612_000;

    timer {
        my @primes = primes-is-prime;
        say "Using .is-prime: @primes[$nth]";
    }
    timer {
        my @primes = primes-sieve($max);
        say "Using a sieve (simple Perl 6 style): @primes[$nth]";
    }
    timer {
        my @primes = primes-sieve2($max);
        say "Using a sieve (optimized): @primes[$nth]";
    }
    timer {
        my @primes = primes-sieve3($max);
        say "Using a sieve (even more optimized): @primes[$nth]";
    }
    timer {
        my @primes = primes-sieve4;
        say "Using a flexible sieve size (further optimized): @primes[$nth]";
    }
    timer {
        my @primes = primes-perl5;
        say "Using a Perl 5 module: @primes[$nth]";
    }
    timer {
        my @primes = primes-primesieve($max);
        say "Using Primesieve module: @primes[$nth]";
    }
    timer {
        my @primes = primes-primesieve-iterator;
        say "Using Primesieve module (iterator): @primes[$nth]";
    }
    timer {
        my @primes = primes-cheat;
        say "Cheating: @primes[$nth]";
    }
}

# 4 year old Linux server, running Rakudo Star 2017.04:
#
# Using .is-prime: 611957
# Elapsed: 216.134s
# Using a sieve (simple Perl 6 style): 611957
# Elapsed: 124.087s
# Using a sieve (optimized): 611957
# Elapsed: 41.129s
# Using a sieve (even more optimized): 611957
# Elapsed: 7.285s
# Using a flexible sieve size (further optimized): 611957
# Elapsed: 3.897s
# Using a Perl 5 module: 611957
# Elapsed: 10.031s
# Using Primesieve module: 611957
# Elapsed: 0.312s
# Using Primesieve module (iterator): 611957
# Elapsed: 1.460s
# Cheating: 611957
# Elapsed: 2.017s