Сводная таблица в SAS

Вы можете использовать PROC SUMMARY для подсчета, а затем использовать PROC TRANSPOSE, чтобы превратить подсчеты в переменные вместо наблюдений. Если вы просто сделаете это напрямую, вы получите пропущенные значения вместо нуля для комбинаций, которые не отображаются. Вы можете выполнить постобработку файла, чтобы заменить отсутствующие значения нулями. Или используйте описанный ниже метод, чтобы построить таблицу CLASSDATA для подачи в PROC SUMMARY, чтобы гарантировать, что все нули включены перед транспонированием.

proc sql noprint ;
 create table classdata as
 select *
 from (select distinct year,month,id1,id2 from have) a
    , (select distinct field_desc from have) b
 ;
quit;
proc summary data=have nway classdata=classdata exclusive ;
  class year month id1 id2 field_desc ;
  output out=counts ;
run;
proc transpose data=counts out=want(drop=_name_);
  by year month id1 id2 ;
  id field_desc ;
  var _freq_;
run;

Вы можете заставить PROC SQL генерировать полные подсчеты рангов напрямую с помощью небольшого количества хитрого SQL. Объедините данные с полным списком значений переменной id и подсчитайте, сколько раз совпадают две переменные id.

proc sql noprint ;
 create table counts as
 select year,month,id1,id2
      , b.field_desc
      , sum(a.field_desc=b.field_desc) as count
 from have a
    , (select distinct field_desc from have) b
 group by year,month,id1,id2,b.field_desc
 order by year,month,id1,id2,b.field_desc
 ;
quit;

Сгенерировать SQL легко. Если количество производных переменных невелико, просто сгенерируйте код в макропеременную. (Если список большой, сгенерируйте код, используя шаг данных, используя либо call execute(), либо записав его в файл и используя %include для его запуска.)

proc sql noprint ;
 select distinct
 catx(' '
     ,'sum(field_desc ='
     ,quote(trim(field_desc))
     ,') as'
     ,nliteral(field_desc)
     )
   into :code separated by ','
   from have
 ;
 create table want as
   select year, month, id1, id2
        , &code
   from have
   group by year, month, id1, id2
  ;
quit;

Если вы хотите сделать это на этапе данных, рассмотрите возможность использования объекта HASH для сбора этих данных. Затем используйте PROC TRANSPOSE или метод генерации кода (как в приведенном выше SQL), чтобы преобразовать наблюдения в переменные.

Именно для этого SAS предлагает PROC.

Оператор CLASS в большинстве процессов (в частности, proc means, proc tabulate) позволяет суммировать данные по различным уровням. Так, например:

proc means data=sashelp.class;
  var height weight;  *the numeric variables you are calculating with;
  class age sex;      *the grouping variables;
  types () age sex age*sex;   *the interactions you want - or use NWAY or WAYS;
run;

Or:

proc tabulate data=sashelp.class;
  var height weight;   *numeric variables to calculate with;
  class age sex;       *grouping variables;
  tables (all age sex age*sex),(height weight)*n;
run;

В зависимости от процедуры у вас есть несколько способов получить эту информацию. У многих есть опция out или оператор output (например, PROC MEANS имеет оператор OUTPUT для этого). Кроме того, ODS OUTPUT позволяет получить доступ ко всему, что выводится на экран в виде таблицы.

ods output table=want;
proc tabulate data=sashelp.class;
  var height weight;
  class age sex;
  tables (all age sex age*sex),(height weight)*n;
run;
ods output close;

--or--

proc tabulate data=sashelp.class out=want;
  var height weight;
  class age sex;
  tables (all age sex age*sex),(height weight)*n;
run;