SAS filevar с несколькими переменными и значением fileref

Вы можете думать о fileref как об указателе на файл, как в C/C++.

Вы абсолютно можете управлять выводом файла, используя значения из набора данных. Вот пример использования первых нескольких наблюдений из данных SASHELP.CARS.

proc sort data=sashelp.cars (where=(make in ('Acura', 'Audi', 'BMW')))
          out=cars;
by make type;
run;

data _null_;
set cars;
by make type;
retain fid;
if first.type then do;
    f_name = catt("c:\temp\",make,"_",type,".txt");
    rc = filename("temp",f_name);
    fid= fopen("temp","o");
    rc = fput(fid,'make,model,type,msrp');
    rc = fappend(fid);
end;

rc = fput(fid,catx(",",make,model,type,msrp));
rc = fappend(fid);

if last.type then do;
    rc = fclose(fid);
end;
run;

Это создает файл CSV для каждой группы MAKE, TYPE, в котором указано название автомобиля и рекомендованная производителем розничная цена.

Для каждой группы:

1. f_name — это имя физического файла для вывода. функции filename() и fopen() открывают файл для вывода. fid — это ссылка на файл.
2. fput() помещает строку в буфер.
3. fappend() добавляет буфер к файлу. Сделайте это для заголовка, а затем один раз для каждой записи.
4. в конце группы закройте файл с помощью fclose()

Ты совершенно прав; вы можете использовать filevar для определения имени файла на основе данных в вашем наборе данных.

Вот простой пример использования sashelp.cars для создания набора файлов, по одному для каждой марки автомобиля.

filename a temp;
data _null_;
  set sashelp.cars;
  outname = cats('c:\temp\',make,'.txt');
  file a filevar=outname dlm=',';
  put make $ model $ mpg_city mpg_highway;
run;

Имя файла a — это ненужное имя файла, потому что оно должно иметь что-то в этом месте синтаксиса. Он ничего не делает (отсюда и temp).

Обратите внимание: используя этот метод, вы должны правильно отсортировать файл (в группах, соответствующих вашим файлам). В противном случае он не будет работать так, как вы хотите. Он не обязательно должен быть упорядочен по этой переменной, но должен быть упорядочен по этой переменной. Так что это нормально:

A
A
B
B
G
G
C
C
D
D

Но не это:

A
B
G
C
D
A
B
G
C
D

Вы также должны убедиться, что у вас есть допустимые имена файлов (поэтому не используйте model в sashelp.cars, если только вы не очистите его, так как в нем много недопустимых символов, таких как \).

Я думаю, вы говорите об опции FILEVAR= в выражении FILE. Это говорит SAS использовать значение определенной переменной, чтобы найти имя файла для записи. Вы можете построить его из чего угодно.

fileref — это псевдоним, который вы создаете, когда используете оператор FILENAME или функцию FILENAME(). Так же, как libref — это псевдоним, который вы создаете, когда используете оператор LIBNAME или функцию LIBNAME().

Таким образом, вы можете определить ссылку на файл, которая указывает на один или несколько файлов.

filename file1 '/project1/source.csv';
filename file2 ('/project1/source1.txt' '/project1/source2.txt');

И затем вы можете использовать ссылку на файл в местах, где вы, возможно, ранее использовали физическое имя файла в кавычках.

infile file1 dsd ;
infile file2 eov=eov ;

Вы также можете использовать fileref для указания каталогов.

filename raw '/project1/' ;

А затем добавьте () для ссылки на определенные файлы в этих каталогах.

infile raw('source.csv') dsd ;
infile raw('source1.txt' 'source2.txt') eov=eov;
file raw('export.csv') dsd ;