Вставка в DB2 из набора данных SAS с сквозным SQL

Сложный способ работы с этим состоял бы в использовании call execute:

data _null_;
set sas_table;
call execute("PROC SQL;
              connect to db2 (user = xxxx database = xxxx password = xxxx);
              execute (
                 insert into xxxx.xxxx (var)
                 values (TIMESTAMP('"||strip(dt_string)||"'))
                ) by db2;
              disconnect from db2;
              quit;");
run;

Где sas_table - это ваш набор данных SAS, содержащий значения даты и времени, хранящиеся в виде строк и в переменной с именем dt_string.

Здесь происходит следующее: для каждого наблюдения в наборе данных SAS будет выполнять аргумент процедуры вызова execute, каждый раз с текущим значением dt_string.

Другой метод, использующий макросы вместо выполнения вызова, делает по сути то же самое:

%macro insert_timestamp;
  %let refid = %sysfunc(open(sas_table));
  %let refrc = %sysfunc(fetch(&refid.));
  %do %while(not &refrc.);
    %let var = %sysfunc(getvarc(&refid.,%sysfunc(varnum(&refid.,dt_string))));

    PROC SQL;
      connect to db2 (user = xxxx database = xxxx password = xxxx);
      execute (insert into xxxx.xxxx (var) values (TIMESTAMP(%str(%')&var.%str(%')))) by db2;
     disconnect from db2;
    quit;

    %let refrc = %sysfunc(fetch(&refid.));
  %end;
  %let refid = %sysfunc(close(&refid.));
%mend;
%insert_timestamp;

РЕДАКТИРОВАТЬ: я думаю, вы также можете загрузить таблицу в DB2 как есть, используя SAS / ACCESS, а затем преобразовать строки в метку времени с помощью sql pass-through. Что-то вроде

libname lib db2 database=xxxx schema=xxxx user=xxxx password=xxxx;
data lib.temp;
set sas_table;
run;
PROC SQL;
    connect to db2 (user = xxxx database = xxxx password = xxxx);
    execute (create table xxxx.xxxx (var TIMESTAMP)) by db2;
    execute (insert into xxxx.xxxx select TIMESTAMP(dt_string) from xxxx.temp) by db2;
    execute (drop table xxxx.temp) by db2;
    disconnect from db2;
quit;