Запрос SPARQL для удаления всех пустых узлов в ресурсе

Я пишу запрос SPARQL, который должен удалить все тройки в этом ресурсе.

prefix oslc: <http://open-services.net/ns/core#>
prefix example: <http://rdf.company.com/ns/something/net#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dcterms: <http://purl.org/dc/terms/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

example:Resource2
        a                oslc:ResourceShape ;
        oslc:describes   example:Resource2 ;
        oslc:property    [ a                      oslc:Property ;
                           oslc:isMemberProperty  true ;
                           oslc:name              "pgn" ;
                           oslc:occurs            oslc:Zero-or-one ;
                           oslc:valueType         xsd:integer ] ;
        dcterms:title    "Resource2"^^rdf:XMLLiteral .

Я пытался:

 DELETE
    { ?s  ?p   ?o } 
  WHERE 
    { 
      ?s  ?p   ?o .
      FILTER  ( ?s IN ( <http://rdf.company.com/ns/something/net#Resource2>))
    }

Однако id не удаляет пустой узел внутри себя:

[ a                      oslc:Property ;
  oslc:isMemberProperty  true ;
  oslc:name              "pgn" ;
  oslc:occurs            oslc:Zero-or-one ;
  oslc:valueType         xsd:integer ]

Это довольно очевидно, потому что фильтр указывает конкретную тему, а пустой узел не имеет этой темы.

Любая идея, как я могу удалить пустой узел?


sparql rdf blank-nodes turtle-rdf
person Yash Khatri    schedule 02.10.2017    source источник

Ответы (1)


arrow_upward
1
arrow_downward

Надеюсь, у вас нет вложенных пустых узлов. Попробуй это:

PREFIX example: <http://rdf.company.com/ns/something/net#>

DELETE {
    ?s  ?p   ?o .
    ?o  ?p1  ?o1 .
}
WHERE {
    VALUES (?s) { (example:Resource2) }
    ?s  ?p  ?o .
    OPTIONAL {
        ?o  ?p1  ?o1  .
        FILTER (isBlank(?o)) 
    }
}

Связанный вопрос: Удалите пустой узел из онтологии с помощью SPARQL UPDATE.

person Stanislav Kralin    schedule 02.10.2017