Как сгруппировать последовательные даты в XSLT?

Это можно прекрасно выразить в XQuery 3 с помощью предложения переворачивающегося окна (https://www.w3.org/TR/xquery-31/#id-tumbling-windows):

for $entry in Root/Entry
for tumbling window $date in $entry//Time_Off_Date/xs:date(.)
start $s when true()
end $e next $n when $n - $e gt xs:dayTimeDuration('P1D')
return string-join(($entry/Employee_ID, $date[1], $date[last()]), '	')

http://xqueryfiddle.liberty-development.net/6qM2e25

Поскольку процессоры XSLT 2, такие как Saxon 9 или XmlPrime, также поддерживают XQuery, это может быть альтернативой использованию XSLT.

Для XSLT вам может понадобиться объяснить, почему вы не хотите использовать рекурсивную функцию.

Если логика заключается в том, что входной XML содержит только отдельные выходные дни, и вы хотите сгруппировать эти отдельные дни, когда они идут подряд, то вы можете использовать xsl:for-each-group для выбора Time_Off_Details с group-starting-with, установленным для элементов, где Time_Off_Date не является последовательным с предыдущим элементом.

Попробуйте этот XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                version="2.0">

  <xsl:output method="text" />
  <xsl:strip-space elements="*" />

  <xsl:template match="Entry">
    <xsl:for-each-group select="Time_Off_Details" 
                        group-starting-with="*[not(xs:date(Time_Off_Date) = xs:date(preceding-sibling::*[1]/Time_Off_Date) + xs:dayTimeDuration('P1D'))]">
        <xsl:value-of select="../Employee_ID" />
        <xsl:text>,</xsl:text>
        <xsl:value-of select="Time_Off_Date" />
        <xsl:text>,</xsl:text>
        <xsl:value-of select="current-group()[last()]/Time_Off_Date" />
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each-group>
  </xsl:template>
</xsl:stylesheet>

Ваша задача может быть выполнена в XSLT 2.0 с помощью for-each-group.

Сначала вам нужно отсортировать все элементы Time_Off_Date по их полному содержимому.

Каждая группа начинается с элемента Time_Off_Date, для которого не существует другого элемента Time_Off_Date с содержимым, равным предыдущей дате по сравнению с текущей датой.

Чтобы вычислить предыдущую дату в виде строки, необходима следующая последовательность:

• Возьмите текущую дату.
• Вычтите период 1 день.
• Отформатируйте его как yyyy-mm-dd.

Затем для каждой группы нужно:

• Прочитайте дату у первого члена группы.
• Прочитайте дату от последнего члена группы.
• Распечатайте Employee_ID и обе даты в нужном формате.

Таким образом, весь скрипт может выглядеть следующим образом:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema">
  <xsl:output method="text"/>

  <xsl:template match="Root">
    <xsl:text>Employee ID,Time Off Start,Time Off End&#xA;</xsl:text>
      <xsl:for-each-group select="Entry/Time_Off_Details/Time_Off_Date"
        group-starting-with=".[not(//Entry/Time_Off_Details/Time_Off_Date[. =
          format-date(xs:date(current()) - xs:dayTimeDuration('P1D'),
          '[Y0001]-[M01]-[D01]')])]">
        <xsl:sort select="."/>
        <xsl:variable name="startDate" select="current-group()[1]"/>
        <xsl:variable name="lastDate" select="current-group()[last()]"/>
        <xsl:value-of select="../../Employee_ID"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="format-date($startDate,'[M01]/[D1]/[Y0001]')"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="format-date($lastDate,'[M01]/[D1]/[Y0001]')"/>
        <xsl:text>&#xA;</xsl:text>
      </xsl:for-each-group>
  </xsl:template>
</xsl:transform>