Преобразование XSL - XML-данные в разные HTML-таблицы

Привет, как бы выглядела таблица стилей XSL, например, для этого кода XML? Я пробовал что-то в соответствии с этим вопросом (ниже), но мой вывод не выглядел так, как я хочу ниже. преобразование XSL - данные XML в таблицу HTML

XML-код

<?xml version="1.0" encoding="utf-8" ?>
<root>
    <sample time="14" label="Test1:cpu_2:usage_high">
        <value>96</value>
    </sample>
    <sample time="14" label="Test1:cpu_2:usage_low">
        <value>1</value>
    </sample>
    <sample time="1" label="Test1:cpu_1:usage_high">
        <value>97</value>
    </sample>
    <sample time="1" label="Test1:cpu_2:usage_low">
        <value>7</value>
    </sample>
    <sample time="1" label="Test1:cpu_1:usage_low">
        <value>6</value>
    </sample>
    <sample time="14" label="Test1:cpu_1:usage_low">
        <value>11</value>
    </sample>
    <sample time="1" label="Test1:cpu_2:usage_high">
        <value>91</value>
    </sample>
    <sample time="14" label="Test1:cpu_1:usage_high">
        <value>89</value>
    </sample>
</root>

HTML-код

<html>
   <body>
      <h2>CPU1</h2>
          <table>
             <thead>
                <tr>
                   <th>Time</th>
                   <th>High</th>
                   <th>Low</th>
                </tr>
             </thead>
             <tbody>
                <tr>
                   <td>1</td>
                   <td>97</td>
                   <td>6</td>
                </tr>
                <tr>
                   <td>14</td>
                   <td>89</td>
                   <td>11</td>
                </tr>
             </tbody>
          </table>
        <h2>CPU2</h2>
          <table>
             <thead>
                <tr>
                   <th>Time</th>
                   <th>High</th>
                   <th>Low</th>
                </tr>
             </thead>
             <tbody>
                <tr>
                   <td>1</td>
                   <td>91</td>
                   <td>7</td>
                </tr>
                <tr>
                   <td>14</td>
                   <td>96</td>
                   <td>1</td>
                </tr>
             </tbody>
          </table>  
   </body>
</html>

J. Hradek 05.03.2018 источник

comment

Что вы пробовали до сих пор (ваш XSLT)? - zx485 05.03.2018

comment

Я попытался сделать тот же принцип, что и в вопросе, о котором я упоминал выше. Я попытался использовать <xsl:for-each group>, но не смог отсортировать данные по двум разным таблицам по имени ЦП в метке атрибута в каждом образце элемента. - J. Hradek 05.03.2018

Ответы (1)

arrow_upward
1
arrow_downward

Сначала вы должны сгруппировать элементы sample по номеру процессора (второй токен в @label при токенизации :).

Затем сгруппируйте по @time, чтобы получить каждую из строк.

Пример...

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/*">
    <html>
      <body>
        <xsl:for-each-group select="sample" group-by="tokenize(@label, ':')[2]">
          <xsl:sort select="current-grouping-key()"/>
          <h2>
            <xsl:value-of select="upper-case(replace(current-grouping-key(), '_', ''))"/>
          </h2>
          <table>
            <thead>
              <tr>
                <th>Time</th>
                <th>High</th>
                <th>Low</th>
              </tr>
            </thead>
            <tbody>
              <xsl:for-each-group select="current-group()" group-by="@time">
                <xsl:sort select="current-grouping-key()"/>
                <tr>
                  <td>
                    <xsl:value-of select="current-grouping-key()"/>
                  </td>
                  <td>
                    <xsl:value-of select="current-group()[ends-with(@label, 'high')]/value"/>
                  </td>
                  <td>
                    <xsl:value-of select="current-group()[ends-with(@label, 'low')]/value"/>
                  </td>
                </tr>
              </xsl:for-each-group>
            </tbody>
          </table>
        </xsl:for-each-group>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

Вывод

<html>
   <body>
      <h2>CPU1</h2>
      <table>
         <thead>
            <tr>
               <th>Time</th>
               <th>High</th>
               <th>Low</th>
            </tr>
         </thead>
         <tbody>
            <tr>
               <td>1</td>
               <td>97</td>
               <td>6</td>
            </tr>
            <tr>
               <td>14</td>
               <td>89</td>
               <td>11</td>
            </tr>
         </tbody>
      </table>
      <h2>CPU2</h2>
      <table>
         <thead>
            <tr>
               <th>Time</th>
               <th>High</th>
               <th>Low</th>
            </tr>
         </thead>
         <tbody>
            <tr>
               <td>1</td>
               <td>91</td>
               <td>7</td>
            </tr>
            <tr>
               <td>14</td>
               <td>96</td>
               <td>1</td>
            </tr>
         </tbody>
      </table>
   </body>
</html>

Рабочий пример можно увидеть здесь: http://xsltfiddle.liberty-development.net/eiQZDbq

Вот еще один вариант, более общий. Он обрабатывает только образцы с атрибутом метки, который имеет 3-й токен...

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:local="local">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:function name="local:format">
    <xsl:param name="str"/>
    <xsl:param name="delim"/>
    <xsl:variable name="tokens" as="item()*">
      <xsl:for-each select="tokenize($str,$delim)">
        <xsl:sequence select="concat(upper-case(substring(.,1,1)),substring(.,2))"/>
      </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="string-join($tokens, ' ')"/>
  </xsl:function>

  <xsl:template match="/*">
    <html>
      <body>
        <xsl:for-each-group select="sample[tokenize(@label,':')[3]]" group-by="tokenize(@label, ':')[2]">
          <xsl:sort select="current-grouping-key()"/>
          <xsl:variable name="cols" select="distinct-values(current-group()/@label/tokenize(.,':')[3])" as="item()*"/>
          <h2>
            <xsl:value-of select="upper-case(replace(current-grouping-key(), '_', ''))"/>
          </h2>
          <table>
            <thead>
              <tr>
                <th>Time</th>
                <xsl:for-each select="$cols">
                  <th>
                    <xsl:value-of select="local:format(.,'_')"/>
                  </th>
                </xsl:for-each>
              </tr>
            </thead>
            <tbody>
              <xsl:for-each-group select="current-group()" group-by="@time">
                <xsl:sort select="current-grouping-key()"/>
                <tr>
                  <td>
                    <xsl:value-of select="current-grouping-key()"/>
                  </td>
                  <xsl:for-each select="$cols">
                    <td>
                      <xsl:value-of select="current-group()[ends-with(@label, current())]/value"/>
                    </td>
                  </xsl:for-each>
                </tr>
              </xsl:for-each-group>
            </tbody>
          </table>
        </xsl:for-each-group>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

Daniel Haley 05.03.2018

comment

Что, если у меня будет образец с label="Test1:resolution"? Таблица стилей также создала для нее таблицу, но мне нужна таблица только для строки внутри метки, разделенной : (Test1:cpu_1:usage_high)? - J. Hradek; 06.03.2018

comment

Я бы изменил выбор в первой группе для каждой группы на: select="sample[contains(@label,'cpu')]". Это обработает только образцы элементов, которые имеют метку, содержащую процессор. - Daniel Haley; 06.03.2018

comment

И есть ли способ, как сделать, если через двоеточие будет, например, название материнской платы? Таким образом, метка может быть Test1:AsusZ370:ok, а также Test1:GigabyteA580:ok, и мне нужна таблица для каждой материнской платы? - J. Hradek; 06.03.2018

comment

@ J.Hradek - я добавил более общий вариант. Надеюсь, это поможет. - Daniel Haley; 06.03.2018

Преобразование XSL - XML-данные в разные HTML-таблицы

Ответы (1)

Похожие вопросы