Суммирование строк над пустой ячейкой до предыдущей пустой ячейки

Это не так сложно сделать с циклом for, может быть, что-то вроде

lastrow = Cells(Rows.Count, "G").End(xlUp).Row
firstrow = 8
TempTotal = 0
for x = firstrow to lastrow + 1
    If Cells(x, "G") <> "" Then
        TempTotal = TempTotal + Cells(x, "G")
    Else:   Cells(x, "G") = TempTotal
            Cells(x, "G").Interior.ColorIndex = 4
            TempTotal = 0
    End if
    Next x

Я сделал редактирование, чтобы сделать его немного проще

Логика кода:

1. Определите последнюю строку с данными в столбце "G"
2. Двигайтесь вниз по ячейке, пока эта строка
3. Если в ячейке есть значение, добавьте его к временной сумме.

4. Если он пуст, введите временную сумму и сбросьте tempTotal до нуля.

   1. Это первая строка, в которой мы выбираем самую последнюю последнюю ячейку в столбце «G», используем для нее End(xlup), чтобы перейти к последней ячейке с данными, и используем .row, чтобы получить номер строки этой ячейки.

   2. Настройте цикл For, который многократно запускает код между строками «for» и «next x», увеличивая значение x от «firstrow» до «lastrow + 1» каждый раз, когда он повторяется (так, если firsrow равен 1, а lastrow равен 1). 100), то он запустит код 100 раз с x = 1,2,3,4,5 и т. д.)

   3. это оператор «если», «‹>» означает не равно, поэтому мы говорим, что если ячейка в строке x, столбец «G» не равна «», которая является пустой строкой (или ничем), тогда мы делаем следующая строка (добавьте ее значение в tempTotal)
   4. если утверждение «Если» неверно (если ячейка пуста), то мы делаем то, что находится под «Другим», и делаем эту ячейку равной TempTotal, меняем ее цвет на зеленый (4 — это цветовой код, они варьируются от 1 до 50 ) и сбросьте temptotal до 0.

Вы были на правильном пути, используя End(xlDown).

Это должно быть намного быстрее, чем цикл по всем ячейкам, потому что он переходит к следующей пустой ячейке и суммирует через WorksheetFunction.Sum.

Option Explicit

Public Sub DoMyStuff()
    Dim ws As Worksheet
    Set ws = Worksheets("Tabelle8") 'define your worksheet here

    Dim FirstCell As Range
    Set FirstCell = ws.Range("G8")

    Dim VeryLastCell As Range 'get very last cell as stop criteria
    Set VeryLastCell = ws.Cells(ws.Rows.Count, "G").End(xlUp)

    Do
        Dim LastCell As Range
        If FirstCell.Offset(1) = vbNullString Then 'test if there is only one cell to sum
            Set LastCell = FirstCell
        Else
            Set LastCell = FirstCell.End(xlDown)
        End If

        With LastCell.Offset(1, 0) 'this is the cell we want to write the sum
            .Value = Application.WorksheetFunction.Sum(ws.Range(FirstCell, LastCell))
            .Interior.Color = RGB(255, 0, 0)
        End With

        Set FirstCell = LastCell.Offset(2, 0)

    Loop While FirstCell.Row < VeryLastCell.Row
End Sub