Устранение моей явной передачи состояния через лайки, монады и прочее

Если вы хотите использовать монаду состояния для передачи инвентаря игрока и состояния мира через функцию pickUp, вот один из подходов:

type State<'s,'a> = State of ('s -> 'a * 's)

type StateBuilder<'s>() =
  member x.Return v : State<'s,_> = State(fun s -> v,s)
  member x.Bind(State v, f) : State<'s,_> =
    State(fun s ->
      let (a,s) = v s
      let (State v') = f a
      v' s)

let withState<'s> = StateBuilder<'s>()

let getState = State(fun s -> s,s)
let putState v = State(fun _ -> (),v)

let runState (State f) init = f init

type Location = Room | Garden
type Thing = { Name : string; Article : string }
type Player = { Location : Location; Objects : Thing list }

let pickUp thing =
  withState {
    let! (player, objects:Map<_,_>) = getState
    let objs = objects.[player.Location]
    let attempt = objs |> List.partition (fun o -> o.Name = thing)    
    match attempt with    
    | [], _ -> 
        return "You cannot get that."
    | thing :: _, things ->    
        let player' = { player with Objects = thing :: player.Objects }        
        let objects' = objects.Add(player.Location, things)
        let msg = sprintf "You are now carrying %s %s" thing.Article thing.Name
        do! putState (player', objects')
        return msg
  }

let player = { Location = Room; Objects = [] }   
let objects =
  [Room, [{ Name = "whiskey"; Article = "some" }; { Name = "bucket"; Article = "a" }]
   Garden, [{ Name = "chain"; Article = "a length of" }]]    
  |> Map.ofList

let (msg, (player', objects')) = 
  (player, objects)
  |> runState (pickUp "bucket")

Если вы хотите использовать изменяемое состояние в F#, то лучше всего просто написать изменяемый объект. Вы можете объявить изменяемый тип Player следующим образом:

type Player(initial:Location, objects:ResizeArray<Thing>) =
  let mutable location = initial
  member x.AddThing(obj) =
    objects.Add(obj)
  member x.Location 
    with get() = location
    and set(v) = location <- v

Использование монад для сокрытия изменяемого состояния не так распространено в F#. Использование монад дает вам практически ту же императивную модель программирования. Он скрывает передачу состояния, но не меняет модель программирования — есть какое-то изменяемое состояние, которое делает невозможным распараллеливание программы.

Если в примере используется мутация, то это, вероятно, потому, что он был разработан императивным способом. Вы можете изменить архитектуру программы, чтобы сделать ее более функциональной. Например, вместо выбора предмета (и изменения игрока) функция pickUp может просто вернуть некоторый объект, представляющий запрос на выбор предмета. Тогда у мира будет некий движок, который оценивает эти запросы (собранные от всех игроков) и вычисляет новое состояние мира.