Измените определенные поля BSEG из обычной структурированной таблицы

Я думаю, вам нужно получить записи из zbseg с ограничением, потому что будет существовать миллион записей, затем получить их из bseg по одной и обновить его, а затем удалить или обновить его флаги из zbseg для повышения производительности.

tables: BSEG, ZBSEG.

data: GT_ZBSEG like ZBSEG occurs 1 with header line,
      GS_BSEG type BSEG.

select *
into table GT_ZBSEG up to 1000 rows
from ZBSEG.

check SY-SUBRC is initial.
check SY-DBCNT is not initial.

loop at GT_ZBSEG.
  select single * from BSEG into GS_BSEG
  where BSEG~MANDT = GT_ZBSEG-MANDT
    and BSEG~BUKRS = GT_ZBSEG-BUKRS
    and BSEG~BELNR = GT_ZBSEG-BELNR
    and BSEG~GJAHR = GT_ZBSEG-GJAHR
    and BSEG~BUZEI = GT_ZBSEG-BUZEI.
  if SY-SUBRC ne 0.
    message E208(00) with 'Record not found!'.
  endif.
  if GS_BSEG-BUZID ne GT_ZBSEG-BUZID
  or GS_BSEG-AUGDT ne GT_ZBSEG-AUGDT.
    move-corresponding GT_ZBSEG to GS_BSEG.
    update BSEG from GS_BSEG.
  endif.
  " delete same records and transfered
  delete ZBSEG from GT_ZBSEG.
endloop.

Вот фрагмент кода, который вы можете использовать для своей задачи. Он основан на динамическом операторе UPDATE, который позволяет обновлять только определенные поля:

DATA: handle      TYPE REF TO data,
      lref_struct TYPE REF TO cl_abap_structdescr,
      source      TYPE string,
      columns     TYPE string,
      keys        TYPE string,
      cond        TYPE string,
      sets        TYPE string.

SELECT tabname FROM dd02l INTO TABLE @DATA(clusters) WHERE tabclass = 'CLUSTER'.

LOOP AT clusters ASSIGNING FIELD-SYMBOL(<cluster>).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( <cluster>-tabname ).
  source = 'Z' && <cluster>-tabname. " name of your ZBSEG-like table
* get key fields
  DATA(key_fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) 
                                     WHERE ( keyflag NE space ) ( line ) ).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( source ).
* get all fields from source reduced table
  DATA(fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) ( line ) ).

* filling SELECT fields and SET clause
  LOOP AT fields ASSIGNING FIELD-SYMBOL(<field>).
    AT FIRST.
      columns = <field>-fieldname.
      CONTINUE.
    ENDAT.
    CONCATENATE columns <field>-fieldname INTO columns SEPARATED BY `, `.
    IF NOT line_exists( key_fields[ fieldname = <field>-fieldname ] ).
      IF sets IS INITIAL.
        sets = <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
      ELSE.
        sets = sets && `, ` && <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
      ENDIF.
    ENDIF.
  ENDLOOP.

* filling key fields and conditions
  LOOP AT key_fields ASSIGNING <field>.
    AT FIRST.
      keys = <field>-fieldname.
      CONTINUE.
    ENDAT.
    CONCATENATE keys <field>-fieldname INTO keys SEPARATED BY `, `.
    IF cond IS INITIAL.
      cond = <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
    ELSE.
      cond = cond && ` AND ` && <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
    ENDIF.
  ENDLOOP.

* constructing reduced table type
  lref_struct ?= cl_abap_typedescr=>describe_by_name( source ).
  CREATE DATA handle TYPE HANDLE lref_struct.
  ASSIGN handle->*  TO FIELD-SYMBOL(<fsym_wa>).

* updating result cluster table
  SELECT (columns)
    FROM (source)
    INTO @<fsym_wa>.
  UPDATE (<cluster>-tabname)
  SET (sets)
  WHERE (cond).
  ENDSELECT.

ENDLOOP.

Эта часть выбирает все таблицы кластера из DD02L и делает предположение, что вы уменьшили таблицу БД с префиксом Z для каждой целевой таблицы кластера. Например. ZBSEG для BSEG, ZBSET для BSET, ZKONV для KONV < / strong> и так далее.