Отступает ли движок Peg.js после просмотра вперед, как это делают регулярные выражения?

Lookahead работает так же, как в движке регулярных выражений.

Этот запрос не соответствует, потому что следующая буква должна быть 'u', а не 'i'.

word = 'q' &'u' 'i' 't'

Этот запрос выполнен успешно:

word = 'q' &'u' 'u' 'i' 't'

Этот запрос выполнен успешно:

word = 'q' 'u' 'i' 't'

Что касается вашего примера, попробуйте что-то в этом роде, вам вообще не нужно использовать просмотр вперед:

expression
    = termPair ( _ delimiter _ termPair )*

termPair
    = term ('.' term)? ' ' term ('.' term)?

term "term"
    = $([a-z0-9]+)

delimiter "delimiter"
    = "."

_ "whitespace"
    = [ \t\n\r]+

EDIT: добавлен еще один пример для комментариев ниже.

expression
    = first:term rest:delimTerm* { return [first].concat(rest); }

delimTerm
    = delimiter t:term { return t; }

term "term"
    = $((!delimiter [a-z0-9. ])+)

delimiter "delimiter"
    = _ "." _

_ "whitespace"
    = [ \t\n\r]+

EDIT: добавлено дополнительное объяснение термина выражение.

Я попытаюсь немного разобрать правило термина $((!delimiter [a-z0-9. ])+).

$() преобразует все внутри в один текстовый узел, например [].join('').

Один «символ» термина — это любой символ [a-z0-9. ], если бы мы хотели упростить его, мы могли бы вместо этого сказать .. Прежде чем сопоставлять символ, мы хотим искать delimiter, если мы находим delimiter, мы перестаем сопоставлять этот символ. Поскольку нам нужно несколько символов, мы делаем все это несколько раз с +.

Думаю, это обычная идиома в парсерах PEG двигаться вперед таким образом. Я узнал об этой идее из документации treetop для сопоставления строки.