Массив JSON в строку с использованием mule dataweave

Вы можете сделать это, обрабатывая все поля как строки, однако учтите, что:

1. Внутренние кавычки должны быть экранированы. В противном случае вывод не является допустимым JSON.
2. Учтите, что значение «package» также не является действительным JSON, если вы хотите его проанализировать. Это должен быть объект (например, "{\" package \ ": ...}")
3. Этот сценарий ожидает, что все массивы будут иметь ровно 1 элемент. Больше элементов игнорируется, меньшее может привести к ошибке. Это не очень надежная конструкция.

Скрипт (не рекомендуется):

%dw 2.0
output application/json

---
package: using (pc = payload.packageConfiguration[0]) (

        " \"packageId\": \"$(pc.packageId[0])\", " ++  
        " \"component\": \"$(pc.component[0])\" "  ++
        " \"fieldName\": \"$(pc.fieldName[0])\" "  ++
        " \"assetUrl\": \"$(pc.assetUrl[0])\" "
 )

Выход:

{
  "package": " \"packageId\": \"AIM_PACKAGE\",  \"component\": \"Handbook\"  \"fieldName\": \"Upload Handbook Document\"  \"assetUrl\": \"sflydamlocation.handbookfilename.pdf\" "
}

Это уродливая конкатенация строк. Вместо этого я бы предложил просто записать желаемый результат в виде объекта JSON.

Скрипт (рекомендуется):

%dw 2.0
output application/dw
var pc = payload.packageConfiguration[0]
---
package: 
    write({
        packageId: pc.packageId[0],  
        component: pc.component[0],  
        fieldName: pc.fieldName[0],  
        assetUrl: pc.assetUrl[0]
        }, "application/json") replace /\n/ with ""

Выход

{
  "package": "{  \"packageId\": \"AIM_PACKAGE\",  \"component\": \"Handbook\",  \"fieldName\": \"Upload Handbook Document\",  \"assetUrl\": \"sflydamlocation.handbookfilename.pdf\"}"
}

Второй скрипт намного чище, меньше подвержен ошибкам и возвращает экранированный объект JSON, который можно было бы использовать как JSON.

Что-то вроде этого должно сработать, если вам не требуется что-то более гибкое. Я предполагаю, что вы работаете с Mule3 / DW1:

%dw 1.0
%output application/json

%var packageConfig = payload.packageConfiguration[0]
---
{
  package: packageConfig mapObject ((value, key) -> {
    (key): value[0]
  })
}