Autocad - автоматическое обновление сгенерированного поля lisp (счетчик макетов)

Как вы поняли, код, присутствующий в файле acaddoc.lsp, будет оцениваться только при запуске чертежа, поэтому значение вашей переменной *LayoutCount* будет правильным только в момент, когда чертеж впервые открыт.

Одним из возможных способов обойти это может быть использование Visual LISP Reactor для обновления значения этой переменной после определенных действий.

Например, вы можете использовать Miscellaneous Reactor следующим образом для обновления значения переменной при изменении активного макета:

(
    (lambda ( )
        (vl-load-com)
        (foreach grp (vlr-reactors :vlr-miscellaneous-reactor)
            (foreach rtr (cdr grp)
                (if (= "layoutcount-reactor" (vlr-data rtr))
                    (vlr-remove rtr)
                )
            )
        )
        (vlr-set-notification
            (vlr-miscellaneous-reactor "layoutcount-reactor"
               '(
                    (:vlr-layoutswitched . layoutswitched-callback)
                )
            )
            'active-document-only
        )
        (defun layoutswitched-callback ( rtr arg )
            (setq *layoutcount* (length (layoutlist)))
        )
        (layoutswitched-callback nil nil)
        (princ)
    )
)

Скопируйте приведенный выше код в acaddoc.lsp, и переменная *layoutcount* будет определена при запуске чертежа и будет обновляться каждый раз при изменении активного макета.

^{Кроме того, нет необходимости удалять Model из списка, возвращаемого функцией layoutlist, так как эта функция возвращает только список макетов Paperspace.}

Однако недостатком использования глобальных переменных для предоставления этой информации является то, что глобальная переменная будет определена в пространстве имен документа только во время активного сеанса AutoCAD, и ее потребуется переопределять для каждого сеанса<. /сильный>.