xmonad `tags ‹- спрашивает (workspaces .config)` магия, как мне это разобрать?

Проще всего просто заставить оба windowMenu и defaultActions работать в монаде X, у которой уже есть соответствующий экземпляр MonadReader. Так:

defaultActions :: X [(String, X ())]
defaultActions = do
    tags <- asks (workspaces . config)
    return ([ ("Cancel menu", return ())
            , ("Close"      , kill)
            , ("Maximize"   , withFocused $ \w -> sendMessage $ maximizeRestore w)
            , ("Minimize"   , withFocused $ \w -> minimizeWindow w)
            ] ++
            [ ("Move to " ++ tag, windows $ W.shift tag) | tag <- tags ])

windowMenu :: X ()
windowMenu = withFocused $ \w -> do
    acts <- defaultActions
    Rectangle x y wh ht <- getSize w
    Rectangle sx sy swh sht <- gets $ screenRect . W.screenDetail . W.current . windowset
    let originFractX = (fi x - fi sx + fi wh / 2) / fi swh
        originFractY = (fi y - fi sy + fi ht / 2) / fi sht
        gsConfig = (buildDefaultGSConfig colorizer)
                    { gs_originFractX = originFractX
                    , gs_originFractY = originFractY }
    runSelectedAction gsConfig acts

Нет необходимости в махинациях в другом ответе, чтобы сделать windowMenu' параметризованной функцией высшего порядка. Если вы действительно хотите создать windowMenu', который позволит вам параметризовать список действий, сделайте это напрямую:

windowMenu' :: [(String, X ())] -> X ()
windowMenu' acts = withFocused $ \w -> do
    Rectangle x y wh ht <- getSize w
    Rectangle sx sy swh sht <- gets $ screenRect . W.screenDetail . W.current . windowset
    let originFractX = (fi x - fi sx + fi wh / 2) / fi swh
        originFractY = (fi y - fi sy + fi ht / 2) / fi sht
        gsConfig = (buildDefaultGSConfig colorizer)
                    { gs_originFractX = originFractX
                    , gs_originFractY = originFractY }
    runSelectedAction gsConfig acts

В таком мире вы можете запустить defaultActions и передать его результат в windowMenu' с помощью (>>=) (или более do нотации):

windowMenu :: X ()
windowMenu = defaultActions >>= windowMenu'
-- OR
windowMenu = do
    acts <- defaultActions
    windowMenu' acts

Цитирую комментарий:

Да, windowMenu имеет тип X (), а мой defaultActs относится к другому типу. Чего я не понимаю, так это того, как запуск лямбды через withFocused предоставляет ей доступ к некоторому дополнительному контексту.

Вы можете использовать asks для получения полей конфигурации таким образом, поскольку существует экземпляр MonadReader XConf X для монада X. MonadReader обычно используется для предоставления такого доступа к конфигурации.

Причина, по которой я спрашиваю, заключается в том, что когда я пытаюсь реорганизовать это в другой функции:

defaultActs :: [(String, X ())]
    defaultActs = do
    tags <- asks (workspaces . config)
    [ ("A: " ++ tag, return ()) | tag <- tags]

Глядя на ваше определение, я подозреваю, что вы намереваетесь defaultActs быть измененным списком тегов рабочей области. Если так, то вы, вероятно, хотите это:

defaultActs :: X [String]
defaultActs = do
    tags <- asks (workspaces . config)
    return [ "A: " ++ tag | tag <- tags]

То есть получить теги из конфигурации, создать модифицированный список и вернуть его в контексте монады X.

Хорошо, благодаря ответу duplode я смог понять это:

defaultActions :: XConf -> [(String, X ())]
defaultActions = do
    tags <- asks (workspaces . config)
    return ([ ("Cancel menu", return ())
            , ("Close"      , kill)
            , ("Maximize"   , withFocused $ \w -> sendMessage $ maximizeRestore w)
            , ("Minimize"   , withFocused $ \w -> minimizeWindow w)
            ] ++
            [ ("Move to " ++ tag, windows $ W.shift tag) | tag <- tags ])

windowMenu' :: (XConf -> [(String, X ())]) -> X ()
windowMenu' actions = withFocused $ \w -> do
    acts <- asks actions
    Rectangle x y wh ht <- getSize w
    Rectangle sx sy swh sht <- gets $ screenRect . W.screenDetail . W.current . windowset
    let originFractX = (fi x - fi sx + fi wh / 2) / fi swh
        originFractY = (fi y - fi sy + fi ht / 2) / fi sht
        gsConfig = (buildDefaultGSConfig colorizer)
                    { gs_originFractX = originFractX
                    , gs_originFractY = originFractY }
    runSelectedAction gsConfig acts

-- now it composes well, and I can pass in my own `actions` to `windowMenu`
windowMenu = windowMenu' defaultActions

Кстати, я не мог заставить его работать как тип X [String] (не знаю, почему), но решение выше, кажется, работает достаточно хорошо. Может быть, он и не самый лучший (не уверен в этом), но он ведет меня туда, куда я хочу.

Не заглядывая ни в какую документацию, мы многое знаем: это в контексте do-нотации для любого типа, необходимого withFocused. По-видимому, он принимает функцию в качестве аргумента, и эта функция должна возвращать монадическое значение некоторого типа. Значение этого блока do-notation должно иметь тот же тип. Он определенно не имеет тип [(String, X ())]. (Ну, ладно, может, так как [a] является монадой, но маловероятно, что это именно тот тип, который withFocused ожидает в качестве результата).

Вы можете узнать, какой у него тип, просмотрев документация:

withFocused :: (Window -> X ()) -> X ()

Поскольку наша do-нотация находится внутри возвращаемого значения лямбды для первого параметра, она должна иметь тип X (). Поэтому,

asks (workspaces . config) :: X t

для некоторых t, которые мы также могли бы узнать, посмотрев тип workspaces. <- связывает это значение t с именем tags обычным способом, который делает do-нотация.